Главная / Action Script 3
Пакетflash.net
Классpublic final class URLRequestHeader
НаследованиеURLRequestHeader Inheritance Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Объект URLRequestHeader инкапсулирует одиночный заголовок запроса HTTP и состоит из имени и значения. Объекты URLRequestHeader используются в свойстве requestHeaders класса URLRequest.

Представленные далее заголовки запросов не используются, при этом ограничения не зависят от регистра (например, Get, get и GET являются недопустимыми). Вдобавок, написанные через дефис термины применяются, если используется символ подчеркивания (например, Content-Length и Content_Length недопустимы):

Accept-Charset, Accept-Encoding, Accept-Ranges, Age, Allow, Allowed, Authorization, Charge-To, Connect, Connection, Content-Length, Content-Location, Content-Range, Cookie, Date, Delete, ETag, Expect, Get, Head, Host, Keep-Alive, Last-Modified, Location, Max-Forwards, Options, Post, Proxy-Authenticate, Proxy-Authorization, Proxy-Connection, Public, Put, Range, Referer, Request-Range, Retry-After, Server, TE, Trace, Trailer, Transfer-Encoding, Upgrade, URI, User-Agent, Vary, Via, Warning, WWW-Authenticate, x-flash-version.

Объекты URLRequestHeader имеют ограниченную длину. Если суммарная длина объекта URLRequestHeader (длина свойства name плюс свойства value) или массива объектов URLRequestHeader objects, использованных в свойстве URLRequest.requestHeaders, превышает допустимую длину, проигрыватель Adobe® Flash® Player создает исключение.

Не все методы, принимающие параметры URLRequest, поддерживают свойство requestHeaders. Дополнительные сведения см. в описании вызываемого метода. Например, методы FileReference.upload() и FileReference.download() не поддерживают свойство URLRequest.requestHeaders.

Вследствие ограниченных возможностей обозревателей, пользовательские заголовки запросов НТТР поддерживаются только для запросов POST, а для GET — нет.

Посмотреть примеры

См. также

URLRequest
URLLoader


Общедоступные свойства
 СвойствоОпределено
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
  name : String
Имя заголовка запроса HTTP (например, Content-Type или SOAPAction).
URLRequestHeader
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
  value : String
Значение, связанное со свойством name (например, text/plain).
URLRequestHeader
Общедоступные методы
 МетодОпределено
  
URLRequestHeader(name:String = "", value:String = "")
Создает новый объект URLRequestHeader, инкапсулирующий одиночный заголовок запроса HTTP.
URLRequestHeader
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
 Inherited
Возвращает строковое представление заданного объекта.
Object
 Inherited
Возвращает элементарное значение заданного объекта.
Object
Сведения о свойстве
nameсвойство
public var name:String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Имя заголовка HTTP-запроса (например, Content-Type или SOAPAction).

valueсвойство 
public var value:String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Значение, связанное со свойством name (например, text/plain).

Сведения о конструкторе
URLRequestHeader()Конструктор
public function URLRequestHeader(name:String = "", value:String = "")

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Создает новый объект URLRequestHeader, инкапсулирующий одиночный заголовок запроса HTTP. Объекты URLRequestHeader используются в свойстве requestHeaders класса URLRequest.

Параметры
name:String (default = "") — Имя заголовка HTTP-запроса (например, Content-Type или SOAPAction).
 
value:String (default = "") — Значение, связанное со свойством name (например, text/plain).
Примеры Как пользоваться примерами
URLRequestHeaderExample.as

В следующем примере отдельный заголовок HTTP-запроса header добавляется в массив для свойства requestHeaders. Заголовок указывает, что приложение должно переправить запрос на исходный сервер, даже если оно имеет кэшированную копию запрашиваемого объекта.
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.net.URLRequestHeader;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequestHeaderExample extends Sprite {
        public function URLRequestHeaderExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var header:URLRequestHeader = new URLRequestHeader("pragma", "no-cache");
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/greeting.cfm");
            request.data = new URLVariables("name=John+Doe");
            request.method = URLRequestMethod.POST;
            request.requestHeaders.push(header);
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}