Главная / Action Script 3
Пакетflash.net
Классpublic final class URLLoaderDataFormat
НаследованиеURLLoaderDataFormat Inheritance Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Класс URLLoaderDataFormat обеспечивает значения, указывающие, каким образом получаются загружаемые данные.

Посмотреть примеры



Общедоступные свойства
 СвойствоОпределено
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
Общедоступные методы
 МетодОпределено
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
 Inherited
Возвращает строковое представление заданного объекта.
Object
 Inherited
Возвращает элементарное значение заданного объекта.
Object
Общедоступные константы
 Константа Определено
  BINARY : String = "binary"
[статические] Указывает, что загружаемые данные получаются в виде необработанных двоичных данных.
URLLoaderDataFormat
  TEXT : String = "text"
[статические] Указывает, что загружаемые данные получаются в виде текста.
URLLoaderDataFormat
  VARIABLES : String = "variables"
[статические] Указывает, что загружаемые данные получаются в виде переменных в кодировке URL.
URLLoaderDataFormat
Сведения о константе
BINARYКонстанта
public static const BINARY:String = "binary"

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Указывает, что загружаемые данные получаются в виде необработанных двоичных данных.

TEXTКонстанта  
public static const TEXT:String = "text"

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Указывает, что загружаемые данные получаются в виде текста.

VARIABLESКонстанта  
public static const VARIABLES:String = "variables"

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Указывает, что загружаемые данные получаются в виде переменных в кодировке URL.

Примеры Как пользоваться примерами
URLLoaderDataFormatExample.as

В следующем примере класс URLLoaderDataFormatExample используется для отображения формата данных и информации о состоянии файла, загруженного при выполнении кода. Это можно сделать, выполнив следующие действия:
  1. Класс конструктора создает экземпляр URLLoader под именем loader и экземпляр URLRequest под именем request, в котором указывается место размещения и имя загружаемого файла.
  2. Объект loader передается методу configureListeners(), который добавляет прослушивателей для каждого из поддерживаемых событий URLLoader:
    • completeHandler(): находится в ожидании события complete, которое отправляется после успешной загрузки TextFile.txt.
    • openHandler(): прослушивает событие open, которое отправляется после начала загрузки (в проигрыватель) файла TextFile.txt.
    • progressHandler(): находится в ожидании событий progress, отправляется при получении данных по мере выполнения операции загрузки.
    • securityErrorHandler(): находится в ожидании событий securityError, которые отправляются, если была совершена попытка обращения к текстовому файлу с применением недопустимого параметра безопасности локального воспроизведения.
    • httpStatusHandler(): находится в ожидании событий httpStatusHandler, которые в данном случае не будут отправлены, так как TextFile.txt является локальным файлом.
    • ioErrorHandler(): находится в ожидании событий ioError, которые могут произойти только при возникновении серьезной проблемы (например, при отсутствии нужного файла).
  3. Затем объект request передается методу loader.load(), который загружает текстовый файл в память с помощью объекта DisplayObject.

Примечания.


package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderDataFormatExample extends Sprite {
        private var source:String = "TextFile.txt";
        private var dataFormat:String = URLLoaderDataFormat.TEXT;
        
        public function URLLoaderDataFormatExample () {
            var loader:URLLoader = new URLLoader();
            loader.dataFormat = dataFormat;
            configureListeners(loader);
            var request:URLRequest = new URLRequest(source);
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Error loading requested document: " + source);
            }
        }

        private function configureListeners(dispatcher:URLLoader):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            switch(loader.dataFormat) {
                case URLLoaderDataFormat.TEXT :
                    trace("completeHandler (text): " + loader.data);
                    break;
                case URLLoaderDataFormat.BINARY :
                    trace("completeHandler (binary): " + loader.data);
                    break;
                case URLLoaderDataFormat.VARIABLES :
                    trace("completeHandler (variables): " + loader.data);
                    break;
            }
        }

        private function httpStatusHandler(event:Event):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}