Главная / Action Script 3
Пакетflash.display
Классpublic class Stage
НаследованиеStage Inheritance DisplayObjectContainer Inheritance InteractiveObject Inheritance DisplayObject Inheritance EventDispatcher Inheritance Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Класс Stage представляет основную область рисования.

Для SWF-содержимого, выполняемого в обозревателе (в Flash® Player), Stage представляет собой всю область отображения содержимого Flash. Для содержимого, выполняемого в приложении AIR, каждый объект NativeWindow имеет соответствующий объект Stage.

К объекту Stage нет глобального доступа. Доступ к нему осуществляется через свойство stage экземпляра DisplayObject.

Класс Stage имеет несколько классов предков — DisplayObjectContainer, InteractiveObject, DisplayObject и EventDispatcher, — от которых он наследует свойства и методы. Многие из этих свойств и методов либо неприменимы к объектам Stage, либо требуют проверки безопасности, когда используются для объекта Stage. Свойства и методы, требующие проверки безопасности, записаны как часть класса Stage.

Следующие наследуемые свойства также неприменимы к объектам Stage. При попытке задать для них значения выдается ошибка IllegalOperationError. Эти свойства можно считывать, но, так как для них невозможно задать значение, они всегда имеют значения по умолчанию.

Некоторые события, которые, казалось бы, являются частью класса Stage, например enterFrame, exitFrame, frameConstructed и render, не могут быть событиями класса Stage, так как существование ссылки на объект Stage не гарантируется в каждой ситуации, в которой используются данные события. Так как эти события не могут быть отправлены объектом Stage, они отправляются каждым экземпляром DisplayObject, что означает, что вы можете добавить прослушиватель событий к любому экземпляру DisplayObject для прослушивания этих событий. Такие события, являющиеся частью класса DisplayObject, называются многоадресными и отличаются от событий, нацеленных на конкретный экземпляр DisplayObject. Два других многоадресных события, activate и deactivate, принадлежат к суперклассу DisplayObject, EventDispatcher. Поведение событий activate и deactivate схоже с поведением многоадресных событий DisplayObject, за исключением того, что эти два события отправляются не только всеми экземплярами DisplayObject, но также всеми экземплярами EventDispatcher и экземплярами других подклассов EventDispatcher. Дополнительную информацию о многоадресных событиях см. в описании класса DisplayObject.

В JavaScript доступ к свойству stage окна, в котором содержится страница HTML, можно получить путем извлечения свойства runtime.nativeWindow.stage. Данное свойство доступно только для содержимого, обрабатываемого в изолированной программной среде безопасности.

Множество свойств и методов Stage относится к объектам Stage, выполняемым в SWF-файлах (в которых используется список отображения ActionScript 3.0). Эти свойства и методы не настолько необходимы в коде JavaScript, выполняемом в приложениях AIR на основе HTML. Для получения сведений об этих свойствах и методах см. справочник по языку ActionScript 3.0.

Следующие свойства Stage наиболее необходимы в приложениях AIR на основе HTML:

Посмотреть примеры

См. также

flash.display.DisplayObject
Основные классы показа
Работа с экранными объектами
Установка свойств рабочей области


Общедоступные свойства
 СвойствоОпределено
 InheritedaccessibilityProperties : AccessibilityProperties
Текущие параметры специальных возможностей для данного экранного объекта.
DisplayObject
  align : String
Значение класса StageAlign, задающее выравнивание рабочей области в проигрывателе Flash Player или обозревателе.
Stage
 Inheritedalpha : Number
Указывает значение альфа-прозрачности заданного объекта.
DisplayObject
 InheritedblendMode : String
Значение класса BlendMode, задающее режим наложения.
DisplayObject
 InheritedblendShader : Shader
[только для записи] Задает затенение, используемое при наложении переднего плана на фон.
DisplayObject
 InheritedcacheAsBitmap : Boolean
При значении true проигрыватель Flash Player кэширует внутреннее растровое представление экранного объекта.
DisplayObject
  colorCorrection : String
Управление цветокоррекцией Flash Player для отображений.
Stage
  colorCorrectionSupport : String
[только для чтения] Определяет выполнение приложения Flash Player в операционной системе, поддерживающей цветокоррекцию, и возможность чтения и распознавания цветового профиля главного (основного) монитора в приложении Flash Player.
Stage
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
 InheritedcontextMenu : ContextMenu
Определяет контекстное меню, связанное с данным объектом.
InteractiveObject
  displayState : String
Значение класса StageDisplayState, задающее состояние отображения.
Stage
 InheriteddoubleClickEnabled : Boolean
Определяет, получает ли объект события doubleClick.
InteractiveObject
 Inheritedfilters : Array
Индексированный массив, который содержит все объекты filter, связанные в настоящий момент с экранным объектом.
DisplayObject
  focus : InteractiveObject
Интерактивный объект с фокусом клавиатуры, либо null, если фокус не установлен, а также если объект с фокусом принадлежит к изолированной программной среде безопасности, доступ к которой отсутствует у вызывающего объекта.
Stage
 InheritedfocusRect : Object
Задает отображение прямоугольной рамки индикатора фокуса для данного объекта.
InteractiveObject
  frameRate : Number
Определяет и задает частоту кадров рабочей области.
Stage
  fullScreenHeight : uint
[только для чтения] Возвращает ту высоту монитора, которая будет использована при мгновенном переходе в полноэкранный режим.
Stage
  fullScreenSourceRect : Rectangle
Flash Player масштабирует конкретный участок рабочей области в полноэкранный режим.
Stage
  fullScreenWidth : uint
[только для чтения] Возвращает ту ширину монитора, которая будет использована при мгновенном переходе в полноэкранный режим.
Stage
  height : Number
Указывает высоту экранного объекта в пикселах.
Stage
 InheritedloaderInfo : LoaderInfo
[только для чтения] Возвращает объект LoaderInfo, содержащий сведения о загрузке файла, к которому принадлежит этот экранный объект.
DisplayObject
 Inheritedmask : DisplayObject
Вызывающий экранный объект маскируется заданным объектом mask.
DisplayObject
  mouseChildren : Boolean
Определяет, включен ли переход между потомками объекта с помощью мыши.
Stage
 InheritedmouseEnabled : Boolean
Определяет, получает ли этот объект сообщения мыши.
InteractiveObject
 InheritedmouseX : Number
[только для чтения] Указывает координату x положения курсора мыши (в пикселах).
DisplayObject
 InheritedmouseY : Number
[только для чтения] Указывает координату y положения курсора мыши (в пикселах).
DisplayObject
 Inheritedname : String
Указывает имя экземпляра DisplayObject.
DisplayObject
  AIR-only nativeWindow : NativeWindow
[только для чтения] Ссылка на объект NativeWindow, содержащий данную рабочую область.
Stage
  numChildren : int
[только для чтения] Возвращает число потомков данного объекта.
Stage
 InheritedopaqueBackground : Object
Определяет, является ли экранный объект непрозрачным с определенным цветом фона.
DisplayObject
 Inheritedparent : DisplayObjectContainer
[только для чтения] Указывает объект DisplayObjectContainer, содержащий данный экранный объект.
DisplayObject
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
  quality : String
Значение класса StageQuality, определяющее, какое качество визуализации следует применять.
Stage
 Inheritedroot : DisplayObject
[только для чтения] В случае с экранным объектом в загруженном SWF-файле свойством root является самый верхний экранный объект в части структуры дерева списка отображения, представленной этим SWF-файлом.
DisplayObject
 Inheritedrotation : Number
Указывает поворот экземпляра DisplayObject относительно его исходной ориентации (в градусах).
DisplayObject
 InheritedrotationX : Number
Обозначает поворот в градусах по оси x экземпляра DisplayObject относительно исходной ориентации по трехмерному родительскому контейнеру.
DisplayObject
 InheritedrotationY : Number
Обозначает поворот в градусах по оси у экземпляра DisplayObject относительно исходной ориентации по трехмерному родительскому контейнеру.
DisplayObject
 InheritedrotationZ : Number
Обозначает поворот в градусах по оси z экземпляра DisplayObject относительно исходной ориентации по трехмерному родительскому контейнеру.
DisplayObject
 Inheritedscale9Grid : Rectangle
Текущая активная сетка масштабирования.
DisplayObject
  scaleMode : String
Значение класса StageScaleMode, задающее режим масштабирования.
Stage
 InheritedscaleX : Number
Указывает горизонтальное масштабирование объекта от точки регистрации (в процентах).
DisplayObject
 InheritedscaleY : Number
Указывает вертикальное масштабирование объекта от точки регистрации (в процентах).
DisplayObject
 InheritedscaleZ : Number
Указывает масштабирование глубины объекта (в процентах) относительно точки регистрации этого объекта.
DisplayObject
 InheritedscrollRect : Rectangle
Прямоугольная область прокрутки экранного объекта.
DisplayObject
  showDefaultContextMenu : Boolean
Задает отображение или скрытие элементов по умолчанию в контекстном меню Flash Player.
Stage
 Inheritedstage : Stage
[только для чтения] Класс Stage экранного объекта.
DisplayObject
  stageFocusRect : Boolean
Определяет, должна ли отображаться светящаяся рамка вокруг объектов в фокусе.
Stage
  stageHeight : int
Текущая высота объекта Stage в пикселах.
Stage
  stageWidth : int
Задает текущую ширину объекта Stage в пикселах.
Stage
  tabChildren : Boolean
Определяет, включен ли переход между потомками объекта с помощью клавиши Tab.
Stage
 InheritedtabEnabled : Boolean
Определяет, включен ли этот объект в последовательность перехода с помощью клавиши Tab.
InteractiveObject
 InheritedtabIndex : int
Задает последовательность перехода между объектами в SWF-файле.
InteractiveObject
  textSnapshot : TextSnapshot
[только для чтения] Возвращает объект TextSnapshot для данного экземпляра DisplayObjectContainer.
Stage
 Inheritedtransform : Transform
Объект со свойствами, относящимися к матрице, преобразованию цвета и пиксельным границам экранного объекта.
DisplayObject
 Inheritedvisible : Boolean
Определяет видимость экранного объекта.
DisplayObject
  width : Number
Указывает ширину экранного объекта в пикселах.
Stage
 Inheritedx : Number
Указывает координату x экземпляра DisplayObject, связанную с локальными координатами родительского DisplayObjectContainer.
DisplayObject
 Inheritedy : Number
Указывает координату y экземпляра DisplayObject, связанную с локальными координатами родительского DisplayObjectContainer.
DisplayObject
 Inheritedz : Number
Указывает положение по оси z экземпляра DisplayObject относительно трехмерного родительского контейнера.
DisplayObject
Общедоступные методы
 МетодОпределено
  
Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer.
Stage
  
Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer.
Stage
  
addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Регистрирует объект прослушивателя события в объекте EventDispatcher, в результате чего прослушиватель будет получать уведомления о событиях.
Stage
 Inherited
Показывает, могут ли ограничения безопасности привести к пропуску каких-либо экранных объектов в списке, возвращаемом в результате вызова метода DisplayObjectContainer.getObjectsUnderPoint() с заданной точкой.
DisplayObjectContainer
  
AIR-only assignFocus(objectToFocus:InteractiveObject, direction:String):void
Задает фокус клавиатуры на интерактивном объекте, указанном в objectToFocus. Направление фокуса устанавливается параметром direction.
Stage
 Inherited
Определяет, является ли заданный экранный объект дочерним объектом экземпляра DisplayObjectContainer или самим экземпляром.
DisplayObjectContainer
  
Передает событие в поток событий.
Stage
 Inherited
getBounds(targetCoordinateSpace:DisplayObject):Rectangle
Возвращает прямоугольник, определяющий область экранного объекта, которая относится к системе координат объекта targetCoordinateSpace.
DisplayObject
 Inherited
Возвращает экземпляр дочернего экранного объекта, существующий в заданной позиции индекса.
DisplayObjectContainer
 Inherited
Возвращает экземпляр дочернего экранного объекта с заданным именем.
DisplayObjectContainer
 Inherited
Возвращает позицию индекса для дочернего экземпляра DisplayObject.
DisplayObjectContainer
 Inherited
Возвращает массив объектов, расположенных ниже заданной позиции и являющихся дочерними объектами любого уровня для данного экземпляра DisplayObjectContainer.
DisplayObjectContainer
 Inherited
getRect(targetCoordinateSpace:DisplayObject):Rectangle
Возвращает прямоугольник, определяющий границу экранного объекта по системе координат, заданной параметром targetCoordinateSpace, за исключением линий фигур.
DisplayObject
 Inherited
Преобразует объект Point из координат рабочей области (глобальных) в координаты экранного объекта (локальные).
DisplayObject
 Inherited
Преобразует двумерный объект Point из координат рабочей области (глобальных) в координаты экранного трехмерного объекта (локальные).
DisplayObject
  
Проверяет наличие у объекта EventDispatcher прослушивателей событий, которые зарегистрированы для получения уведомлений о событиях определенного типа.
Stage
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Оценивает экранный объект, чтобы определить, перекрывает ли он экранный объект obj или пересекается с ним.
DisplayObject
 Inherited
hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean
Вычисляет экранный объект, чтобы определить, перекрывает ли он точку, заданную координатами x и y, или пересекает ее.
DisplayObject
  
Вызов метода invalidate() предписывает проигрывателю Flash Player оповестить экранные объекты о следующей возможности визуализации списка отображения (например, когда точка воспроизведения приближается к новому кадру).
Stage
  
Определяет, должно ли свойство Stage.focus возвращать значение null по соображениям безопасности.
Stage
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Преобразует трехмерный объект point из координат трехмерного экранного объекта (локальных) в двухмерный объект point с координатами рабочей области (глобальными).
DisplayObject
 Inherited
Преобразует объект point из координат экранного объекта (локальных) в координаты рабочей области (глобальные).
DisplayObject
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Удаляет заданный дочерний объект DisplayObject из списка потомков экземпляра DisplayObjectContainer.
DisplayObjectContainer
  
Удаляет дочерний DisplayObject из заданной позиции индекса в списке потомков DisplayObjectContainer.
Stage
 Inherited
removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void
Удаляет прослушиватель из объекта EventDispatcher.
EventDispatcher
  
Изменяет положение существующего потомка в DisplayObjectContainer.
Stage
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
 Inherited
Меняет местами (в порядке "от начала к концу") два заданных дочерних объекта.
DisplayObjectContainer
  
swapChildrenAt(index1:int, index2:int):void
Меняет местами (в порядке "от начала к концу") дочерние объекты, расположенные в двух заданных позициях индекса в списке потомков.
Stage
 Inherited
Возвращает строковое представление заданного объекта.
Object
 Inherited
Возвращает элементарное значение заданного объекта.
Object
  
Проверяет, зарегистрирован ли прослушиватель событий в объекте EventDispatcher или в любом из его предков для получения уведомлений о событиях определенного типа.
Stage
События
 Событие Сводка Определено
 Inherited[многоадресное событие] Отправляется, когда проигрыватель Flash Player перемещается в фокус операционной системы и становится активным.EventDispatcher
 InheritedОтправляется, когда экранный объект добавляется в список отображения.DisplayObject
 InheritedОтправляется, когда экранный объект добавляется к списку отображения в рабочей области, либо непосредственно, либо путем добавления поддерева, содержащего экранный объект.DisplayObject
 InheritedОтправляется, когда пользователь выбирает команду "Удалить" в контекстном меню текста.InteractiveObject
 InheritedОтправляется, когда пользователь нажимает и отпускает главную кнопку на указывающем устройстве над одним и тем же объектом InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Копировать", или выбирает команду "Копировать" из контекстного меню.InteractiveObject
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Вырезать", или выбирает команду "Вырезать" из контекстного меню.InteractiveObject
 Inherited[многоадресное событие] Отправляется, когда проигрыватель Flash Player покидает фокус операционной системы и становится неактивным.EventDispatcher
 InheritedОтправляется, когда пользователь дважды нажимает и отпускает главную кнопку на указывающем устройстве над одним и тем же объектом InteractiveObject, а флаг doubleClickEnabled для этого объекта имеет значение true.InteractiveObject
 Inherited[многоадресное событие] Отправляется, когда точка воспроизведения переходит в новый кадр.DisplayObject
 Inherited[многоадресное событие] Отправляется, когда точка воспроизведения покидает текущий кадр.DisplayObject
 InheritedОтправляется, когда экранный объект перемещается в фокус.InteractiveObject
 InheritedОтправляется, когда экранный объект покидает фокус.InteractiveObject
 Inherited[многоадресное событие] Отправляется после завершения работы конструкторов экранных объектов кадра до выполнения сценариев кадра.DisplayObject
  Отправляется, когда объект Stage переходит в полноэкранный режим или выходит из этого режима.Stage
 InheritedОтправляется, когда пользователь нажимает клавишу.InteractiveObject
 InheritedОтправляется, когда пользователь пытается изменить фокус с помощью клавиатуры.InteractiveObject
 InheritedОтправляется, когда пользователь отпускает клавишу.InteractiveObject
 InheritedОтправляется, когда пользователь нажимает кнопку на указывающем устройстве над экземпляром InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется, когда пользователь пытается изменить фокус с помощью указывающего устройства.InteractiveObject
  Отправляется объектом Stage, когда курсор мыши покидает рабочую область.Stage
 InheritedОтправляется, когда пользователь перемещает указывающее устройство в момент, когда курсор находится над объектом InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь перемещает указывающее устройство от экземпляра InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь наводит указывающее устройству на экземпляр InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется, когда пользователь отпускает кнопку на указывающем устройстве над экземпляром InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется, когда пользователь вращает колесико мыши над экземпляром InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Вставить", или выбирает команду "Вставить" из контекстного меню.InteractiveObject
 InheritedОтправляется перед удалением экранного объекта из списка отображения.DisplayObject
 InheritedОтправляется перед удалением экранного объекта из списка отображения, либо непосредственно, либо путем удаления поддерева, содержащего экранный объект.DisplayObject
 Inherited[многоадресное событие] Отправляется перед обновлением и визуализацией списка отображения.DisplayObject
  Отправляется, когда свойство scaleMode объекта Stage установлено в значение StageScaleMode.NO_SCALE и изменяется размер SWF-файла.Stage
 InheritedОтправляется, когда пользователь перемещает указывающее устройство от экземпляра InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь наводит указывающее устройство на экземпляр InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Выделить все", или выбирает команду "Выделить все" из контекстного меню.InteractiveObject
 InheritedОтправляется, когда изменяется значение свойства tabChildren объекта.InteractiveObject
 InheritedОтправляется при изменении флага tabEnabled объекта.InteractiveObject
 InheritedОтправляется, когда изменяется значение свойства tabIndex объекта.InteractiveObject
Сведения о свойстве
alignсвойство
align:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Значение класса StageAlign, задающее выравнивание рабочей области в проигрывателе Flash Player или обозревателе. Ниже приводятся допустимые значения.

ЗначениеВыравнивание по вертикалиПо горизонтали
StageAlign.TOPВерхний крайЦентр
StageAlign.BOTTOMНижний крайЦентр
StageAlign.LEFTЦентрСлева
StageAlign.RIGHTЦентрСправа
StageAlign.TOP_LEFTВерхний крайСлева
StageAlign.TOP_RIGHTВерхний крайСправа
StageAlign.BOTTOM_LEFTНижний крайСлева
StageAlign.BOTTOM_RIGHTНижний крайСправа

Свойство align доступно только для объекта, находящегося в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.



Реализация
    public function get align():String
    public function set align(value:String):void

См. также

colorCorrectionсвойство 
colorCorrection:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Управление цветокоррекцией Flash Player для отображений. Коррекция цвета срабатывает, только если главному монитору назначен действительный профиль ICC, задающий конкретные цветовые атрибуты устройства. По умолчанию в приложении Flash Player предпринимается попытка сопоставления цветокоррекции хоста (обычно обозревателя).

Используйте свойство Stage.colorCorrectionSupport для определения доступности цветокоррекции в текущей системе и состоянии по умолчанию. Если коррекция цвета доступна, все цвета в рабочей области должны находиться в пространстве цветов sRGB, которое на данный момент является наиболее распространенным. Во время цветовой коррекции исходные профили устройств ввода игнорируются. Коррекция цветов на вводе не применяется. На цветовой профиль IIC главного монитора накладывается только вывод рабочей области.

Обычно, активация управления цветом делает передачу цвета более точной, улучшает преобразование, позволяет точнее осуществлять цветопробу и эффективно отображать цвета независимо от программного материала. Имейте ввиду, что управление цветом не делает преобразование идеальным, так как цветовые гаммы различных устройств расходятся между собой и отличаются от палитр исходных изображений. Подобным образом, при использовании управления цветом не исключается необходимость использовать пользовательские или измененные профили. Профили цветов зависят от обозревателей, операционных систем (ОС), расширений ОС, устройств вывода и поддержки со стороны приложения.

При применении коррекции цвета производительность Flash Player снижается. В Flash Player коррекция цвета реализована в качестве документа стиля коррекции цвета, так как все ролики SWF являются документами со встроенными профилями sRGB. Используйте свойство Stage.colorCorrectionSupport, чтобы во время отображения документа SWF в цветовом пространстве проигрыватель Flash Player осуществлял процесс коррекции цвета наиболее подходящим образом. Flash Player может компенсировать различия между мониторами, но не устройствами ввода (видеотехникой/сканнером и так далее).

Тремя возможными значениями являются строки с соответствующими константами в классе flash.display.ColorCorrection:



Реализация
    public function get colorCorrection():String
    public function set colorCorrection(value:String):void

См. также

colorCorrectionSupportсвойство 
colorCorrectionSupport:String  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Определяет выполнение приложения Flash Player в операционной системе, поддерживающей цветокоррекцию, и возможность чтения и распознавания цветового профиля главного (основного) монитора в приложении Flash Player. Это свойство также возвращает состояние цветокоррекции по умолчанию в хост-системе (обычно обозревателе). Текущими возвращаемыми значениями могут быть следующие:

Тремя возможными значениями являются строки с соответствующими константами в классе flash.display.ColorCorrectionSupport:



Реализация
    public function get colorCorrectionSupport():String

См. также

displayStateсвойство 
displayState:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Значение класса StageDisplayState, задающее состояние отображения. Ниже приводятся допустимые значения.

Масштабирование видео в полноэкранном режиме определяется значением scaleMode (которое задается при помощи свойства Stage.scaleMode параметрами тегов embed SWF-файла в файле HTML). Если для свойства scaleMode задано значение noScale при переходе приложения в полноэкранный режим, свойства объекта Stage width и height обновляются, и объект Stage получает событие resize.

Следующие ограничения действуют для SWF-файлов, проигрываемых на странице HTML (не для тех, что выполняются в автономном проигрывателе Flash Player и не выполняются в среде AIR):

Данные ограничения не действуют для содержимого SWF, выполняемого в автономном Flash Player или в приложении AIR. AIR поддерживает интерактивный полноэкранный режим, который допускает ввод с клавиатуры.

На время воспроизведения ролика AIR в полноэкранном режиме экранная заставка ОС и управление питанием отключаются и становятся активными только при выходе из полноэкранного режима или завершении воспроизведения ролика.



Реализация
    public function get displayState():String
    public function set displayState(value:String):void

Выдает
SecurityError — Вызов свойства displayState объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0. При попытке настроить свойство displayState, когда отображается диалоговое окно параметров без отклика пользователя или если атрибуту allowFullScreen HTML-тегов param или embed не назначено значение true, появляется ошибка безопасности.

См. также


Пример
В следующем примере создается интерактивная демонстрация того, как создавать полноэкранное представление путем модификации свойства displayState.

Примечание. Вследствие ограничений, установленных из соображений безопасности, полноэкранный режим можно запускать только в определенных ситуациях, например, если пользователь щелкнул кнопку или нажал клавишу. При запуске в обозревателе свойство allowFullScreen должно иметь значение true.

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}
focusсвойство 
focus:InteractiveObject  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Интерактивный объект с фокусом клавиатуры, либо null, если фокус не установлен, а также если объект с фокусом принадлежит к изолированной программной среде безопасности, доступ к которой отсутствует у вызывающего объекта.



Реализация
    public function get focus():InteractiveObject
    public function set focus(value:InteractiveObject):void

Выдает
Error — Выдает ошибку, если фокус нельзя перевести на цель.
frameRateсвойство 
frameRate:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Определяет и задает частоту кадров рабочей области. Частота кадров определяется как число кадров в секунду. По умолчанию используется значение частоты кадров первого загруженного SWF-файла. Допустимые значения частоты кадров находятся в диапазоне 0,01 — 1000 кадров в секунду.

Примечание. Приложение может не воспринимать параметры высокой частоты, если целевая платформа недостаточно быстрая или если проигрыватель синхронизируется с интервалами пробела по вертикали дисплея (обычно это 60 Гц на ЖК-мониторах). В некоторых случаях целевая платформа также может выбирать более низкую максимальную частоту кадров, если ожидает высокий процент использования ЦП.

При работе с содержимым в Adobe AIR настройка свойства frameRate одного объекта Stage приводит к изменению частоты кадров всех объектов Stage (используемых разными объектами NativeWindow).



Реализация
    public function get frameRate():Number
    public function set frameRate(value:Number):void

Выдает
SecurityError — Вызов метода frameRate объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
fullScreenHeightсвойство 
fullScreenHeight:uint  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.115.0

Возвращает ту высоту монитора, которая будет использована при мгновенном переходе в полноэкранный режим. Если в системе установлено несколько мониторов, то используется тот из них, на котором в данный момент отображается большая часть рабочей области.

Примечание. Если у пользователя есть возможность перемещать обозреватель с одного монитора на другой между получением значения и переходом в полноэкранный режим, то это значение будет неправильным. Если значение получено в обработчике событий, задающем для Stage.displayState значение StageDisplayState.FULL_SCREEN, то значение будет правильным.

Это высота монитора в пикселах, она равна высоте рабочей области, если Stage.align для задано значение StageAlign.TOP_LEFT, а для Stage.scaleModeStageScaleMode.NO_SCALE.



Реализация
    public function get fullScreenHeight():uint

См. также


Пример
В данном примере создается зеленый прямоугольник размером с рабочую область, а поверх него накладывается красный квадрат, активируемый в качестве кнопки. Щелчок по красному квадрату запускает обработчика событий enterFullScreen(), который задает свойство fullScreenSourceRect и входит в полноэкранный режим. Чтобы задать свойство fullScreenSourceRect, обработчик событий начинает с местоположения и размеров красного квадрата. Затем он сравнивает соотношение сторон (ширина, разделенная на высоту) красного квадрата с соотношением сторон рабочей области, имеющего ширину и высоту полного экрана, чтобы развернуть прямоугольник (fullScreenSourceRect) в соответствии с соотношением сторон экрана. В результате, красный квадрат занимает всю высоту монитора, а по бокам виден зеленый фон. Если бы не соблюдалось соотношение сторон, то вместо зеленого фона по бокам был бы виден фон рабочей области (по умолчанию белый).

Примечание. Протестируйте этот пример в обозревателе. В диалоговом окне "Параметры публикации Flash", на вкладке "HTML" выберите шаблон "Только Flash — Разрешить полноэкранный режим". Укажите Flash Player версии 9.0.115.0 и не забудьте выбрать форматы Flash и HTML на вкладке "Форматы". Затем опубликуйте и откройте полученный HTML-файл в обозревателе.


import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}
fullScreenSourceRectсвойство 
fullScreenSourceRect:Rectangle  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.115.0

Flash Player масштабирует конкретный участок рабочей области в полноэкранный режим. Если есть возможность, проигрыватель Flash Player выполняет масштабирование с использованием аппаратных средств, включая графическую карту и видеокарту на компьютере пользователя. В этом случае отображение содержания, как правило, начинается намного быстрее, чем при масштабирование с помощью программных средств.

Когда этому свойству задано значение допустимого прямоугольника, а свойство displayState настроено на полноэкранный режим, проигрыватель Flash Player масштабирует заданную область. Фактический размер рабочей области в пикселах в ActionScript не изменяется. Проигрыватель Flash Player использует ограничение минимального размера прямоугольника, чтобы показать сообщение "Нажмите "Esc" для выхода из полноэкранного режима". Обычно минимальный размер бывает около 260 на 30 пикселов, но он может варьироваться в зависимости от платформы и версии Flash Player.

Это свойство можно настраивать, только когда проигрыватель не находится в полноэкранном режиме. Для правильного использования этого свойства его необходимо настроить первым, и только потом выбирать для свойства displayState полноэкранный режим, как показано в примерах кода.

Чтобы включить масштабирование, задайте свойство fullScreenSourceRect объекту прямоугольника.

  
  // valid, will enable hardware scaling
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240); 
  

Чтобы отключить масштабирование, задайте fullScreenSourceRect=null в ActionScript 3.0 и undefined в ActionScript 2.0.

  stage.fullScreenSourceRect = null;
  

Конечный пользователь может отключить в параметрах отображения проигрывателя Flash Player аппаратное масштабирование, включенное по умолчанию. Дополнительные сведения см. на странице www.adobe.com/go/display_settings_ru.



Реализация
    public function get fullScreenSourceRect():Rectangle
    public function set fullScreenSourceRect(value:Rectangle):void

См. также


Пример
Чтобы использовать аппаратное масштабирование, необходимо задать полноэкранный режим для всего рабочей области или его части. Следующий код ActionScript 3.0 задает полноэкранный режим для всего рабочей области.
 
import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}
В следующем примере пользователь может переключать воспроизведение видео с полноэкранного режима в нормальный и обратно щелчком по рабочей области. Если SWF-файл, рассматриваемый в данном примере, воспроизводится в проигрывателе Flash Player версии 9.0.115.0 или более поздней, то для улучшения полноэкранного масштабирования при отображении будет использоваться аппаратное ускорение.

Прежде чем использовать полноэкранный режим с аппаратным масштабированием, необходимо выполнить следующие условия:

  1. проигрыватель Flash Player версии 9.0.115.0 или более поздней, а также поддерживающий его инструмент разработки;
  2. необходимо изменить HTML-шаблоны с целью поддержки полноэкранного режима; атрибуту allowFullScreen необходимо задать значение true для тегов object и embed. (Сценарии, создающие теги для внедрения SWF, также должны разрешать переход в полноэкранный режим.) Примеры файлов, которые можно использовать для Flex Builder, см. в статье Exploring full-screen mode in Flash Player 9 (Полноэкранный режим в проигрывателе Flash Player 9).
  3. У приложения должны быть разрешение и доступ к видеофайлу FLV. В данном примере предполагается, что файл Flash Video (FLV) находится в том же каталоге, что и SWF-файл.
  4. Пользователь должен разрешить доступ для полноэкранного режима.
  5. Дополнительные сведения об аппаратном масштабировании см. в статье Поддержка видео с высоким разрешением H.264 и аудио формата AAC в проигрывателе Flash Player.

FLV-файл загружается с использованием объектов NetConnection и NetStream. Так как FLV-файл находится в том же каталоге, что и SWF-файл и будет подключаться через HTTP, то параметру метода NetConnection.connect() задается значение null. Объект connect NetConnection сообщает свое состояние, отправляя событие netStatus, вызывающее метод netStatusHandler(). Метод netStatusHandler() проверяет, успешно ли установлено подключение и вызывает метод connectStream(), который создает объект NetStream, принимающий в качестве параметра объект NetConnection. Он также создает видеообъект и прилагаемый к нему объект NetStream. Затем видеообъект добавляется в список отображения и поток включается на воспроизведение. Так как видеофайл FLV не содержит метаданных или информации о ключевых точках, отправляется событие AsyncError. Необходимо настроить прослушиватель для обработки этого события. В данном примере прослушиватель настроен, он игнорирует событие. Также для объекта NetStream настраивается другой прослушиватель для события netStatus. Он будет отображать сообщение об ошибке, если поток не найден. (Обратите внимание, что метод netStatusHandler() можно использовать для обработки любого объема информации о состоянии потока или подключения.)

Когда становятся доступны свойства и методы загруженного SWF-файла, вызывается метод createMouseListener(). Он настраивает прослушивателя событий для щелчка мыши по рабочей области. Метод toggleFullScreen() проверяет, находится ли состояние отображения в полноэкранном или нормальном режиме. Если режим нормальный, размер видеообъекта равен размеру видеопотока. Для свойства fullScreenSourceRect выбирается прямоугольник, соответствующий размерам видеообъекта. Затем для свойства Stage.displayMode задается полный экран, в результате чего видео в исходном прямоугольнике развернется на весь экран. Если выполняются системные требования, графические аппаратные средства компьютера будут использоваться для оптимизации производительности полноэкранной визуализации видеоролика, и состояние отображения переходит в полноэкранный режим. Чтобы улавливать любые ошибки безопасности, которые могут возникнуть при переходе в полноэкранный режим, используется try...catch. (Обратите внимание, что состояние отображения должно переводиться на полноэкранный режим после того, как задано свойство fullScreenSourceRect.) Перед переключением в нормальный режим ширина и высота видеообъекта возвращаются к сохраненным исходным значениям. Если этого не сделать, ширина и высота будут определяться изменениями, внесенными в видеообъект для полноэкранного режима.

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}
fullScreenWidthсвойство 
fullScreenWidth:uint  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.115.0

Возвращает ту ширину монитора, которая будет использована при мгновенном переходе в полноэкранный режим. Если в системе установлено несколько мониторов, то используется тот из них, на котором в данный момент отображается большая часть рабочей области.

Примечание. Если у пользователя есть возможность перемещать обозреватель с одного монитора на другой между получением значения и переходом в полноэкранный режим, то это значение будет неправильным. Если значение получено в обработчике событий, задающем для Stage.displayState значение StageDisplayState.FULL_SCREEN, то значение будет правильным.

Это ширина монитора в пикселах, она равна ширине рабочей области, если Stage.align для задано значение StageAlign.TOP_LEFT, а для Stage.scaleModeStageScaleMode.NO_SCALE.



Реализация
    public function get fullScreenWidth():uint

См. также


Пример
В данном примере создается зеленый прямоугольник размером с рабочую область, а поверх него накладывается красный квадрат, активируемый в качестве кнопки. Щелчок по красному квадрату запускает обработчика событий enterFullScreen(), который задает свойство fullScreenSourceRect и входит в полноэкранный режим. Чтобы задать свойство fullScreenSourceRect, обработчик событий начинает с местоположения и размеров красного квадрата. Затем он сравнивает соотношение сторон (ширина, разделенная на высоту) красного квадрата с соотношением сторон рабочей области, имеющего ширину и высоту полного экрана, чтобы развернуть прямоугольник (fullScreenSourceRect) в соответствии с соотношением сторон экрана. В результате, красный квадрат занимает всю высоту монитора, а по бокам виден зеленый фон. Если бы не соблюдалось соотношение сторон, то вместо зеленого фона по бокам был бы виден фон рабочей области (по умолчанию белый).

Примечание. Протестируйте этот пример в обозревателе. В диалоговом окне "Параметры публикации Flash", на вкладке "HTML" выберите шаблон "Только Flash — Разрешить полноэкранный режим". Укажите Flash Player версии 9.0.115.0 и не забудьте выбрать форматы Flash и HTML на вкладке "Форматы". Затем опубликуйте и откройте полученный HTML-файл в обозревателе.


import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}
heightсвойство 
height:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Указывает высоту экранного объекта в пикселах. Высота вычисляется на основе границ содержимого экранного объекта. Когда задается свойство height, соответствующим образом изменяется и свойство scaleY, как показано в следующем коде.

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleY) // 1;
    rect.height = 200;
    trace(rect.scaleY) // 2;

За исключением объектов TextField и Video, экранные объекты без содержимого (например, пустой спрайт), имеют высоту 0, даже если задать свойству height другое значение.



Реализация
    public function get height():Number
    public function set height(value:Number):void

Выдает
SecurityError — Ссылка на свойство height объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
 
IllegalOperationError — Абсолютно недопустимо настраивать свойство height объекта Stage, даже если вызывающий объект является его владельцем (главный SWF-файл).
mouseChildrenсвойство 
mouseChildren:Boolean  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Определяет, включен ли переход между потомками объекта с помощью мыши. Если объект реагирует на мышь, пользователь может взаимодействовать с ним с помощью мыши. Значение по умолчанию — true.

Это свойство удобно использовать, когда кнопка создается с помощью экземпляра класса Sprite (а не класса SimpleButton). Когда для создания кнопки используется экземпляр Sprite, при желании можно украсить кнопку с помощью метода addChild(), добавив дополнительные экземпляры Sprite. Этот процесс может вызывать непредвиденное поведение событий мыши, так как целевым объектом события мыши вместо родительского экземпляра могут стать экземпляры Sprite, добавленные в качестве потомков. Чтобы родительский экземпляр гарантированно быть целевым объектом событий мыши, можно задать его свойству mouseChildren значение false.

При настройке данного свойства события не отправляются. Чтобы создать интерактивные функции, необходимо использовать метод addEventListener().



Реализация
    public function get mouseChildren():Boolean
    public function set mouseChildren(value:Boolean):void

Выдает
SecurityError — Ссылка на свойство mouseChildren объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
AIR-only nativeWindowсвойство 
nativeWindow:NativeWindow  [только для чтения]

Версии среды выполнения:  1.0

Ссылка на объект NativeWindow, содержащий данную рабочую область.

Данное окно представляет собственное окно ОС, а рабочая область — его содержимое. Данное свойство может быть использовано только при работе в среде AIR. В проигрывателе Flash Player (при просмотре содержимого в обозревателе) значением данного свойства является null.



Реализация
    public function get nativeWindow():NativeWindow
numChildrenсвойство 
numChildren:int  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает число потомков данного объекта.



Реализация
    public function get numChildren():int

Выдает
SecurityError — Ссылка на свойство numChildren объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
qualityсвойство 
quality:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Значение класса StageQuality, определяющее, какое качество визуализации следует применять. Ниже приводятся допустимые значения.

Более высокие параметры качества обеспечивают более качественную визуализацию масштабированных растровых изображений. Однако, это происходит за счет увеличения нагрузки на ресурсы системы. В частности, параметр высокого качества при визуализации масштабированного видео может привести к падению частоты кадров.

При воспроизведении содержимого в Adobe AIR можно установить параметр quality в значение StageQuality.BEST или StageQuality.HIGH (значением по умолчанию является StageQuality.HIGH). Изменение значения параметра на другое ни к чему не приводит (значение свойства остается неизменным).

При работе с содержимым в Adobe AIR настройка свойства quality одного объекта Stage приводит к изменению качества визуализации всех объектов Stage (используемых разными объектами NativeWindow).

Примечание. Операционная система использует шрифты устройства, вследствие чего на них не влияет свойство quality.



Реализация
    public function get quality():String
    public function set quality(value:String):void

Выдает
SecurityError — Вызов свойства quality объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

scaleModeсвойство 
scaleMode:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Значение класса StageScaleMode, задающее режим масштабирования. Ниже приводятся допустимые значения.



Реализация
    public function get scaleMode():String
    public function set scaleMode(value:String):void

Выдает
SecurityError — Вызов метода scaleMode объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

showDefaultContextMenuсвойство 
showDefaultContextMenu:Boolean  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает отображение или скрытие элементов по умолчанию в контекстном меню Flash Player.

Если свойство showDefaultContextMenu имеет значение true (по умолчанию), то появляются все элементы контекстного меню. Если свойство showDefaultContextMenu имеет значение false, отображаются только элементы меню "Параметры" и "О проигрывателе Adobe Flash Player".



Реализация
    public function get showDefaultContextMenu():Boolean
    public function set showDefaultContextMenu(value:Boolean):void

Выдает
SecurityError — Вызов свойства showDefaultContextMenu объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
stageFocusRectсвойство 
stageFocusRect:Boolean  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Определяет, должна ли отображаться светящаяся рамка вокруг объектов в фокусе.



Реализация
    public function get stageFocusRect():Boolean
    public function set stageFocusRect(value:Boolean):void

Выдает
SecurityError — Вызов свойства stageFocusRect объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
stageHeightсвойство 
stageHeight:int  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Текущая высота объекта Stage в пикселах.

Если задать для свойства Stage.scaleMode значение StageScaleMode.NO_SCALE, когда пользователь изменяет размеры окна, содержимое рабочей области сохраняет заданный размер, а свойство stageHeight изменяется, отражая новую высоту области экрана, занимаемой SWF-файлом. (В остальных режимах масштабирования свойство stageHeight всегда отражает исходную высоту SWF-файла.) Можно добавить прослушиватель для события resize, а затем использовать свойство stageHeight класса Stage, чтобы определять фактические размеры в пикселах измененного окна проигрывателя Flash Player. Прослушиватель событий позволяет контролировать, как содержимое экрана корректируется, когда пользователь изменяет размер окна.

Примечание. На HTML-странице, содержащей SWF-файл атрибуты height тегов object и embed должны быть выражены в процентах (например, 100%), а не в пикселах. Если параметры определяются кодом JavaScript, то параметр height метода AC_FL_RunContent() также необходимо настроить на представление в процентах. Эти проценты применяются к значению stageHeight.



Реализация
    public function get stageHeight():int
    public function set stageHeight(value:int):void

Выдает
SecurityError — Вызов свойства stageHeight объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

stageWidthсвойство 
stageWidth:int  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает текущую ширину объекта Stage в пикселах.

Если задать для свойства Stage.scaleMode значение StageScaleMode.NO_SCALE, когда пользователь изменяет размеры окна, содержимое рабочей области сохраняет заданный размер, а свойство stageWidth изменяется, отражая новую ширину области экрана, занимаемой SWF-файлом. (В остальных режимах масштабирования свойство stageWidth всегда отражает исходную ширину SWF-файла.) Можно добавить прослушиватель для события resize, а затем использовать свойство stageWidth класса Stage, чтобы определять фактические размеры в пикселах измененного окна проигрывателя Flash Player. Прослушиватель событий позволяет контролировать, как содержимое экрана корректируется, когда пользователь изменяет размер окна.

Примечание. На HTML-странице, содержащей SWF-файл атрибуты width тегов object и embed должны быть выражены в процентах (например, 100%), а не в пикселах. Если параметры определяются кодом JavaScript, то параметр width метода AC_FL_RunContent() также необходимо настроить на представление в процентах. Эти проценты применяются к значению stageWidth.



Реализация
    public function get stageWidth():int
    public function set stageWidth(value:int):void

Выдает
SecurityError — Вызов свойства stageWidth объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

tabChildrenсвойство 
tabChildren:Boolean  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Определяет, включен ли переход между потомками объекта с помощью клавиши Tab. Включает или отключает переход между потомками объекта с помощью клавиши Tab. Значение по умолчанию — true.



Реализация
    public function get tabChildren():Boolean
    public function set tabChildren(value:Boolean):void

Выдает
SecurityError — Ссылка на свойство tabChildren объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
textSnapshotсвойство 
textSnapshot:TextSnapshot  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает объект TextSnapshot для данного экземпляра DisplayObjectContainer.



Реализация
    public function get textSnapshot():TextSnapshot

Выдает
IllegalOperationError — Ссылка на свойство textSnapshot объекта Stage приводит к созданию исключения, так как класс Stage не реализует это свойство. Во избежание этого нужно вызвать свойство textSnapshot контейнера экранного объекта, не содержащего объект Stage.
widthсвойство 
width:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Указывает ширину экранного объекта в пикселах. Ширина вычисляется на основе границ содержимого экранного объекта. Когда задается свойство width, соответствующим образом изменяется и свойство scaleX, как показано в следующем коде.

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleX) // 1;
    rect.width = 200;
    trace(rect.scaleX) // 2;

За исключением объектов TextField и Video, экранные объекты без содержимого (например, пустой спрайт), имеют ширину 0, даже если задать свойству width другое значение.



Реализация
    public function get width():Number
    public function set width(value:Number):void

Выдает
SecurityError — Ссылка на свойство width объекта Stage приводит к созданию исключения для всех вызывающих объектов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
 
IllegalOperationError — Абсолютно недопустимо настраивать свойство width объекта Stage, даже если вы являетесь его владельцем.
Сведения о методе
addChild()метод
override public function addChild(child:DisplayObject):DisplayObject

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer. Потомок добавляется перед (сверху) всех остальных потомков в данном экземпляре DisplayObjectContainer. (Чтобы добавить потомка в конкретную позицию в индексе, используйте метод addChildAt().)

Если добавляется объект, предком которого уже является другой контейнер экранных объектов, то он удаляется из списка потомков старого контейнера.

Параметры

child:DisplayObject — Экземпляр DisplayObject для добавления в качестве потомка данного экземпляра DisplayObjectContainer.

Возвращает
DisplayObject — Экземпляр DisplayObject, передаваемый в параметре child.

Выдает
SecurityError — Вызов метода addChild() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

addChildAt()метод 
override public function addChildAt(child:DisplayObject, index:int):DisplayObject

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer. Потомок добавляется в указанной позиции индекса. Индекс 0 обозначает конец списка отображения для данного объекта DisplayObjectContainer.

Так, в следующем примере показано три разных объекта с именами a, b и c в позициях индекса 0, 2 и 1 соответственно.

b над c над a

Если добавляется объект, предком которого уже является другой контейнер экранных объектов, то он удаляется из списка потомков старого контейнера.

Параметры

child:DisplayObject — Экземпляр DisplayObject для добавления в качестве потомка данного экземпляра DisplayObjectContainer.
 
index:int — Позиция индекса, в которую добавляется дочерний объект. Если указать занятую на данный момент позицию индекса, дочерний объект, существующий на этой и на этой позиции, и все выше расположенные позиции перемещаются на одну позицию вверх в списке потомков.

Возвращает
DisplayObject — Экземпляр DisplayObject, передаваемый в параметре child.

Выдает
SecurityError — Вызов метода addChildAt() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

addEventListener()метод 
override public function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Регистрирует объект прослушивателя события в объекте EventDispatcher, в результате чего прослушиватель будет получать уведомления о событиях. Регистрировать прослушиватели событий можно во всех узлах списка отображения для определенного типа события, фазы и приоритета.

После успешной регистрации прослушивателя событий нельзя изменить его приоритет путем дополнительных вызовов метода addEventListener(). Чтобы изменить приоритет прослушивателя, необходимо сначала вызвать метод removeListener(). Затем можно зарегистрировать прослушиватель еще раз с новым уровнем приоритета.

Следует учесть, что после регистрации прослушивателя последующие вызовы метода addEventListener() с другим значением свойства type или useCapture приводят к регистрации другого прослушивателя. Например, если сначала был зарегистрирован прослушиватель со свойством useCapture в значении true, он прослушивает события только в фазе захвата. Если вызвать метод addEventListener() еще раз с тем же объектом прослушивателя, но со свойством useCapture в значении false, то будет два прослушивателя: один — прослушивающий в фазе захвата, а другой — в фазах назначения и восходящей цепочки.

Нельзя зарегистрировать прослушиватель событий только для фазы цели или только для фазы пузырей. Эти фазы объединяются при регистрации, так как фаза пузырей применяется только к предкам целевого узла.

Если прослушиватель событий больше не нужен, его можно удалить, вызвав метод removeEventListener(); иначе могут возникнуть проблемы с памятью. Объекты с зарегистрированным прослушивателями событий не очищаются из памяти автоматически, так как сборщик мусора не удаляет объекты, на которые есть ссылки.

Копирование экземпляра EventDispatcher не приведет к копированию всех присоединенных к нему прослушивателей событий. (Если для вновь созданного узла требуется прослушиватель событий, его необходимо добавить после создания узла.) Однако если экземпляр EventDispatcher перемещается, все зарегистрированные для него прослушиватели событий перемещаются вместе с ним.

Если прослушиватель регистрируется для узла в тот момент, когда на нем обрабатывается событие, то в текущей фазе он не запускается, однако может запуститься в следующей фазе потока события, например в фазе пузырей.

Если прослушиватель событий удаляется из узла в момент обработки события, он все равно запускается текущими действиями. После удаления прослушиватель событий больше не вызывается (если не будет снова зарегистрирован для дальнейшей обработки).

Параметры

type:String — Тип события.
 
listener:Function — Функция прослушивателя, обрабатывающая событие. Эта функция должна принимать объект Event в качестве единственного параметра и не должна что-либо возвращать, как показано в примере:

function(evt:Event):void

У функции может быть любое имя.

 
useCapture:Boolean (default = false) — Определяет, работает ли прослушиватель в фазе захвата или в фазах цели и пузырей. Если useCapture имеет значение true, прослушиватель обрабатывает событие только в фазе захвата, а в фазе цели и пузырей — нет. Если useCapture имеет значение false, прослушиватель обрабатывает событие только в фазе цели или пузырей. Чтобы прослушивать событие во всех трех фазах, необходимо вызвать addEventListener дважды: один раз с useCapture в значении true, а другой — с useCapture в значении false.
 
priority:int (default = 0) — Уровень приоритета прослушивателя событий. Приоритет определяется 32-разрядным целым числом со знаком. Чем больше число, тем выше приоритет. Все прослушиватели событий с приоритетом n обрабатываются перед прослушивателями с приоритетом n-1. Если у двух или более прослушивателей одинаковый приоритет, они обрабатываются в порядке добавления. Значение приоритета по умолчанию равно 0.
 
useWeakReference:Boolean (default = false) — Определяет сильную или слабую степень ссылки на прослушиватель. Сильная ссылка (по умолчанию) запрещает прослушивателю выполнять сборку мусора. Слабая ссылка не препятствует этому.

Функции элементов на уровне класса не подвергаются очистке, поэтому useWeakReference может иметь значение true для функций элементов на уровне класса, не опасаясь их очистки. Если задать для useWeakReference значение true для прослушивателя, который является вложенной внутренней функцией, то он будет очищен и перестанет быть постоянным. Если создаются ссылки на внутреннюю функцию (путем ее сохранения в другой переменной), то она не будет очищаться и останется постоянной.


Выдает
SecurityError — Вызов метода addEventListener объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этой ситуации владелец объекта Stage должен предоставить разрешение домену вызывающего файла путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

AIR-only assignFocus()метод 
public function assignFocus(objectToFocus:InteractiveObject, direction:String):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0

Задает фокус клавиатуры на интерактивном объекте, указанном в objectToFocus. Направление фокуса устанавливается параметром direction.

Направление фокуса должно задаваться приложением (или средой приложения). Как такового встроенного принципа расположения интерактивных объектов не существует, однако, для их упорядочения можно использовать ряд доступных свойств. Например, можно сортировать интерактивные объекты в рабочей области по их положению в списке отображения. Вызов метода assignFocus() идентичен параметру свойства Stage.focus с дополнительной возможностью указывать направление, откуда этот фокус поступает.

После получения фокуса objectToFocus отправляет событие focusIn. Свойство direction объекта FocusEvent сообщает о настройке параметра direction.

При назначении объекта HTMLLoader параметру objectToFocus объект HTMLLoader выбирает подходящий объект для передачи фокуса в HTML DOM, принимая во внимание значение параметра direction. При использовании FocusDirection.BOTTOM фокус передается объекту в HTML DOM, который находится в конце списка отображения. При использовании FocusDirection.TOP фокус передается объекту в HTML DOM, который находится в начале списка отображения. При использовании NONE объект HTMLLoader получает фокус, а его текущий элемент с фокусом не меняется.

Параметры

objectToFocus:InteractiveObject — Объект, на который следует переместить фокус или null, чтобы убрать фокус с любого элемента в рабочей области.
 
direction:String — Направление, по которому фокусируется objectToFocus. Подходящие значения перечислены в виде констант в классе FocusDirection.


Выдает
Error — Если фокус не может быть установлен на цели или тип направления неверный.

См. также

dispatchEvent()метод 
override public function dispatchEvent(event:Event):Boolean

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Передает событие в поток событий. Целью события является объект EventDispatcher, для которого вызывается метод dispatchEvent().

Параметры

event:Event — Объект Event, отправляемый в поток событий. Если осуществляется повторная отправка события, автоматически создается его клон. После отправки события нельзя изменить его свойство target, поэтому необходимо создать новую копию события, чтобы обеспечить правильное выполнение повторной отправки.

Возвращает
Boolean — Значение true, если событие было успешно отправлено. Значение false указывает на ошибку или на то, что для события был вызван метод preventDefault().

Выдает
SecurityError — Вызов метода dispatchEvent() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
hasEventListener()метод 
override public function hasEventListener(type:String):Boolean

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Проверяет наличие у объекта EventDispatcher прослушивателей событий, которые зарегистрированы для получения уведомлений о событиях определенного типа. Это позволяет определить, где объект EventDispatcher изменил обработку типа события в иерархии потока событий. Чтобы определить, запускает ли на самом деле определенный тип событий прослушиватель, используйте метод willTrigger().

Разница между hasEventListener() и willTrigger() заключается в том, что hasEventListener() просматривает только тот объект, которому принадлежит, а willTrigger() просматривает весь поток событий для события, указанного в параметре type.

Когда метод hasEventListener() вызывается из объекта LoaderInfo, учитываются только те прослушиватели, к которым есть доступ у вызывающего объекта.

Параметры

type:String — Тип события.

Возвращает
Boolean — Значение true, если прослушиватель заданного типа зарегистрирован; false, если нет.

Выдает
SecurityError — Вызов метода hasEventListener() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
invalidate()метод 
public function invalidate():void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Вызов метода invalidate() предписывает проигрывателю Flash Player оповестить экранные объекты о следующей возможности визуализации списка отображения (например, когда точка воспроизведения приближается к новому кадру). После вызова методаinvalidate() при дальнейшей визуализации списка отображения проигрыватель Flash Player отправляет событие render каждому экранному объекту, зарегистрированному для прослушивания события render. Метод invalidate() необходимо вызвать каждый раз, когда нужно, чтобы проигрыватель Flash Player отправлял события render.

Событие render дает возможность вносить изменения в список отображения непосредственно перед его визуализацией. Это позволяет откладывать обновления списка отображения до самой последней возможности. Это может увеличить производительность путем предотвращения ненужных обновлений экрана.

Событие render отправляется только тем экранным объектам, которые находятся в том же защищенном домене, что и код, вызывающий метод stage.invalidate(), или экранным объектам из защищенного домена, которому предоставлено разрешение через метод Security.allowDomain().

См. также

isFocusInaccessible()метод 
public function isFocusInaccessible():Boolean

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Определяет, должно ли свойство Stage.focus возвращать значение null по соображениям безопасности. Другими словами, isFocusInaccessible имеет значение true, если объект в фокусе принадлежит к изолированной программной среде безопасности, к которой у SWF-файла нет доступа.

Возвращает
Booleantrue, если объект в фокусе принадлежит к изолированной программной среде безопасности, к которой у SWF-файла нет доступа.
removeChildAt()метод 
override public function removeChildAt(index:int):DisplayObject

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Удаляет дочерний DisplayObject из заданной позиции индекса в списке потомков DisplayObjectContainer. Свойство parent удаленного потомка получает значение null, а сам объект очищается, если нет других ссылок на потомка. Позиции индекса экранных объектов, расположенных над потомком в DisplayObjectContainer уменьшаются на 1.

Сборка мусора — это процесс, с помощью которого проигрыватель Flash Player перераспределяет неиспользуемую память. Когда на переменную или объект больше нет ссылок или он хранится в другом месте, сборщик мусора очищает и утилизирует память, которую он занимал, при условии отсутствия ссылок

Параметры

index:int — Дочерний индекс объекта DisplayObject для удаления.

Возвращает
DisplayObject — Удаленный экземпляр DisplayObject.

Выдает
SecurityError — Вызов метода removeChildAt() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец данного объекта может предоставить разрешение домену вызывающего файла путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
setChildIndex()метод 
override public function setChildIndex(child:DisplayObject, index:int):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Изменяет положение существующего потомка в DisplayObjectContainer. Это отражается на иерархическом представлении дочерних объектов. Так, в следующем примере показано три разных объекта с именами a, b и c в позициях индекса 0, 1 и 2 соответственно.

c над b над a

Когда используется метод setChildIndex() и указывается уже занятая позиция индекса, меняются только позиции между прежней и новой позицией экранного объекта. Все остальные остаются без изменения. Если потомок перемещается на более НИЗКУЮ позицию, позиции всех потомков между этими позициями станут на 1 ВЫШЕ. Если потомок перемещается на более ВЫСОКУЮ позицию, позиции всех потомков между этими позициями станут на 1 НИЖЕ. Например, если контейнер экранных объектов из прошлого примера имеет имя container, можно поменять позициями экранные объекты с именами a и b, вызвав следующий код:

container.setChildIndex(container.getChildAt(1), 0);

В результате этого объекты выстраиваются следующим образом:

c над a над b

Параметры

child:DisplayObject — Дочерний экземпляр DisplayObject, для которого нужно изменить номер индекса.
 
index:int — Полученный в результате номер индекса для дочернего экранного объекта child.


Выдает
SecurityError — Вызов метода addChildIndex() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
swapChildrenAt()метод 
override public function swapChildrenAt(index1:int, index2:int):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Меняет местами (в порядке "от начала к концу") дочерние объекты, расположенные в двух заданных позициях индекса в списке потомков. Все остальные дочерние объекты в контейнере экранных объектов остаются на прежних позициях.

Параметры

index1:int — Позиция индекса первого дочернего объекта.
 
index2:int — Позиция индекса второго дочернего объекта.


Выдает
SecurityError — Вызов метода swapChildrenAt() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владельцы объекта могут предоставить разрешение домену вызывающего файла путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
willTrigger()метод 
override public function willTrigger(type:String):Boolean

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Проверяет, зарегистрирован ли прослушиватель событий в объекте EventDispatcher или в любом из его предков для получения уведомлений о событиях определенного типа. Этот метод возвращает значение true, если прослушиватель событий запускается в любой фазе потока событий, когда событие заданного типа отправляется данному объекту EventDispatcher или его потомкам.

Разница между методами hasEventListener() и willTrigger() заключается в том, что hasEventListener() просматривает только тот объект, которому принадлежит, а willTrigger() просматривает весь поток событий для события, указанного в параметре type.

Когда метод willTrigger() вызывается из объекта LoaderInfo, учитываются только те прослушиватели, к которым есть доступ у вызывающего объекта.

Параметры

type:String — Тип события.

Возвращает
Boolean — Значение true, если прослушиватель заданного типа будет запущен; false, если нет.

Выдает
SecurityError — Вызов метода willTrigger() объекта Stage приводит к созданию исключения для всех вызывающих файлов, находящихся не в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.
Сведения о событии
fullScreen Событие
Тип объекта события: flash.events.FullScreenEvent
свойство FullScreenEvent.type = flash.events.FullScreenEvent.FULL_SCREEN

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Отправляется, когда объект Stage переходит в полноэкранный режим или выходит из этого режима. Изменение в полноэкранном режиме можно инициировать через ActionScript, либо при нажатии комбинации клавиш пользователем, либо если текущий фокус покидает окно, находящееся в полноэкранном режиме.

Константа FullScreenEvent.FULL_SCREEN определяет значение свойства type для объекта события fullScreen.

Данное событие имеет следующие свойства.

СвойствоЗначение
fullScreentrue, если состояние отображения — на весь экран или false, если состояние обычное.
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
targetОбъект Stage.
mouseLeave Событие  
Тип объекта события: flash.events.Event
свойство Event.type = flash.events.Event.MOUSE_LEAVE

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Отправляется объектом Stage, когда курсор мыши покидает рабочую область.

Константа Event.MOUSE_LEAVE определяет значение свойства type объекта события mouseLeave.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
targetОбъект Stage. Свойство target не всегда является объектом из списка отображения, для которого зарегистрирован прослушиватель событий. Используйте свойство currentTarget, чтобы обратиться к объекту в списке отображения, обрабатывающему событие в данный момент.
resize Событие  
Тип объекта события: flash.events.Event
свойство Event.type = flash.events.Event.RESIZE

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Отправляется, когда свойство scaleMode объекта Stage установлено в значение StageScaleMode.NO_SCALE и изменяется размер SWF-файла.

Константа Event.RESIZE определяет значение свойства type объекта события resize.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
targetОбъект Stage.
Примеры Как пользоваться примерами
StageExample.as

В следующем примере используется класс StageExample для отправки событий при активации или изменении размера рабочей области. Это можно сделать, выполнив следующие действия.
  1. Сначала конструктор класса настраивает приложение Flash для фиксации, независимо от размера окна проигрывателя Flash Player, а затем добавляет два прослушивателя событий с методами activateHandler() и resizeHandler().
  2. Метод activateHandler() запускается при щелчке левой кнопкой мыши.
  3. Метод resizeHandler() запускается при изменении размеров рабочего стола.
package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}