Главная / Action Script 3
Пакетfl.controls
Классpublic class Slider
НаследованиеSlider Inheritance UIComponent Inheritance Sprite Inheritance DisplayObjectContainer Inheritance InteractiveObject Inheritance DisplayObject Inheritance EventDispatcher Inheritance Object
Реализует IFocusManagerComponent

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Компонент Slider дает пользователям возможность выбрать значение путем перемещения ползунка между крайними точками дорожки ползунка. Текущее значение компонента Slider определяется относительным местоположением ползунка между конечными точками ползунка, которые задаются значениями minimum и maximum компонента Slider.

Посмотреть примеры

См. также

SliderEvent


Общедоступные свойства
 СвойствоОпределено
 InheritedaccessibilityProperties : AccessibilityProperties
Текущие параметры специальных возможностей для данного экранного объекта.
DisplayObject
 Inheritedalpha : Number
Указывает значение альфа-прозрачности заданного объекта.
DisplayObject
 InheritedblendMode : String
Значение класса BlendMode, задающее режим наложения.
DisplayObject
 InheritedblendShader : Shader
[только для записи] Задает затенение, используемое при наложении переднего плана на фон.
DisplayObject
 InheritedbuttonMode : Boolean
Задает режим кнопки данного спрайта.
Sprite
 InheritedcacheAsBitmap : Boolean
При значении true проигрыватель Flash Player кэширует внутреннее растровое представление экранного объекта.
DisplayObject
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
 InheritedcontextMenu : ContextMenu
Определяет контекстное меню, связанное с данным объектом.
InteractiveObject
  direction : String
Задает направление ползунка.
Slider
 InheriteddoubleClickEnabled : Boolean
Определяет, получает ли объект события doubleClick.
InteractiveObject
 InheriteddropTarget : DisplayObject
[только для чтения] Определяет экранный объект, над которым перетаскивается спрайт, либо на котором спрайт был отпущен.
Sprite
  enabled : Boolean
Определяет или задает значение, указывающее, поддерживает ли компонент взаимодействие с пользователем.
Slider
 Inheritedfilters : Array
Индексированный массив, который содержит все объекты filter, связанные в настоящий момент с экранным объектом.
DisplayObject
 InheritedfocusEnabled : Boolean
Определяет или задает логическое значение, указывающее, может ли компонент принимать фокус при щелчке пользователя.
UIComponent
 InheritedfocusManager : IFocusManager
Определяет или задает объект FocusManager, управляющий фокусом для этого компонента и компонентов, находящихся на том же уровне иерархии.
UIComponent
 InheritedfocusRect : Object
Задает отображение прямоугольной рамки индикатора фокуса для данного объекта.
InteractiveObject
 Inheritedgraphics : Graphics
[только для чтения] Задает объект Graphics, принадлежащий данному спрайту, в котором могут выполняться команды векторного рисования.
Sprite
 Inheritedheight : Number
Определяет или задает высоту компонента (в пикселах).
UIComponent
 InheritedhitArea : Sprite
Определяет другой спрайт в качестве области щелчка для спрайта.
Sprite
  liveDragging : Boolean
[только для чтения] Определяет или задает логическое значение, управляющее непрерывной отправкой события SliderEvent.CHANGE при перемещении ползунка.
Slider
 InheritedloaderInfo : LoaderInfo
[только для чтения] Возвращает объект LoaderInfo, содержащий сведения о загрузке файла, к которому принадлежит этот экранный объект.
DisplayObject
 Inheritedmask : DisplayObject
Вызывающий экранный объект маскируется заданным объектом mask.
DisplayObject
  maximum : Number
Максимальное значение, допустимое для экземпляра компонента Slider.
Slider
  minimum : Number
Минимальное значение, допустимое для экземпляра компонента Slider.
Slider
 InheritedmouseChildren : Boolean
Определяет, включен ли переход между потомками объекта с помощью мыши.
DisplayObjectContainer
 InheritedmouseEnabled : Boolean
Определяет, получает ли этот объект сообщения мыши.
InteractiveObject
 InheritedmouseFocusEnabled : Boolean
Определяет или задает значение, указывающее, может ли компонент принимать фокус при щелчке пользователя.
UIComponent
 InheritedmouseX : Number
[только для чтения] Указывает координату x положения курсора мыши (в пикселах).
DisplayObject
 InheritedmouseY : Number
[только для чтения] Указывает координату y положения курсора мыши (в пикселах).
DisplayObject
 Inheritedname : String
Указывает имя экземпляра DisplayObject.
DisplayObject
 InheritednumChildren : int
[только для чтения] Возвращает число потомков данного объекта.
DisplayObjectContainer
 InheritedopaqueBackground : Object
Определяет, является ли экранный объект непрозрачным с определенным цветом фона.
DisplayObject
 Inheritedparent : DisplayObjectContainer
[только для чтения] Указывает объект DisplayObjectContainer, содержащий данный экранный объект.
DisplayObject
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
 Inheritedroot : DisplayObject
[только для чтения] В случае с экранным объектом в загруженном SWF-файле свойством root является самый верхний экранный объект в части структуры дерева списка отображения, представленной этим SWF-файлом.
DisplayObject
 Inheritedrotation : Number
Указывает поворот экземпляра DisplayObject относительно его исходной ориентации (в градусах).
DisplayObject
 InheritedrotationX : Number
Обозначает поворот в градусах по оси x экземпляра DisplayObject относительно исходной ориентации по трехмерному родительскому контейнеру.
DisplayObject
 InheritedrotationY : Number
Обозначает поворот в градусах по оси у экземпляра DisplayObject относительно исходной ориентации по трехмерному родительскому контейнеру.
DisplayObject
 InheritedrotationZ : Number
Обозначает поворот в градусах по оси z экземпляра DisplayObject относительно исходной ориентации по трехмерному родительскому контейнеру.
DisplayObject
 Inheritedscale9Grid : Rectangle
Текущая активная сетка масштабирования.
DisplayObject
 InheritedscaleX : Number
Умножает текущую ширину компонента на коэффициент масштабирования.
UIComponent
 InheritedscaleY : Number
Умножает текущую высоту компонента на коэффициент масштабирования.
UIComponent
 InheritedscaleZ : Number
Указывает масштабирование глубины объекта (в процентах) относительно точки регистрации этого объекта.
DisplayObject
 InheritedscrollRect : Rectangle
Прямоугольная область прокрутки экранного объекта.
DisplayObject
  snapInterval : Number
Определяет или задает значение, на которое увеличивается или уменьшается значение при перемещении ползунка пользователем.
Slider
 InheritedsoundTransform : SoundTransform
Управляет звуком в данном спрайте.
Sprite
 Inheritedstage : Stage
[только для чтения] Класс Stage экранного объекта.
DisplayObject
 InheritedtabChildren : Boolean
Определяет, включен ли переход между потомками объекта с помощью клавиши Tab.
DisplayObjectContainer
 InheritedtabEnabled : Boolean
Определяет, включен ли этот объект в последовательность перехода с помощью клавиши Tab.
InteractiveObject
 InheritedtabIndex : int
Задает последовательность перехода между объектами в SWF-файле.
InteractiveObject
 InheritedtextSnapshot : TextSnapshot
[только для чтения] Возвращает объект TextSnapshot для данного экземпляра DisplayObjectContainer.
DisplayObjectContainer
  tickInterval : Number
Промежутки между контрольными метками относительно максимального значения компонента.
Slider
 Inheritedtransform : Transform
Объект со свойствами, относящимися к матрице, преобразованию цвета и пиксельным границам экранного объекта.
DisplayObject
 InheriteduseHandCursor : Boolean
Логическое значение, определяющее, должен ли отображаться указатель "рука" при наведении указателя мыши на спрайт, в котором свойство buttonMode имеет значение true.
Sprite
  value : Number
Определяет или задает текущее значение компонента Slider.
Slider
 Inheritedversion : String = "3.0.0.16"
Номер версии компонентов.
UIComponent
 Inheritedvisible : Boolean
Определяет или задает значение, указывающее, видим ли текущий экземпляр компонента.
UIComponent
 Inheritedwidth : Number
Определяет или задает ширину компонента (в пикселах).
UIComponent
 Inheritedx : Number
Определяет или задает координату, представляющую положение компонента по оси X в пределах родительского контейнера.
UIComponent
 Inheritedy : Number
Определяет или задает координату, представляющую положение компонента по оси Y в пределах родительского контейнера.
UIComponent
 Inheritedz : Number
Указывает положение по оси z экземпляра DisplayObject относительно трехмерного родительского контейнера.
DisplayObject
Общедоступные методы
 МетодОпределено
  
Создает новый экземпляр компонента Slider.
Slider
 Inherited
Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer.
DisplayObjectContainer
 Inherited
Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer.
DisplayObjectContainer
 Inherited
addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Регистрирует объект прослушивателя события в объекте EventDispatcher, в результате чего прослушиватель будет получать уведомления о событиях.
EventDispatcher
 Inherited
Показывает, могут ли ограничения безопасности привести к пропуску каких-либо экранных объектов в списке, возвращаемом в результате вызова метода DisplayObjectContainer.getObjectsUnderPoint() с заданной точкой.
DisplayObjectContainer
 Inherited
Удаляет свойство style для экземпляра компонента.
UIComponent
 Inherited
Определяет, является ли заданный экранный объект дочерним объектом экземпляра DisplayObjectContainer или самим экземпляром.
DisplayObjectContainer
 Inherited
Передает событие в поток событий.
EventDispatcher
 Inherited
Отображает или скрывает индикатор фокуса этого компонента.
UIComponent
 Inherited
Инициирует немедленную операцию отрисовки без аннулирования всех элементов (в отличие от метода invalidateNow).
UIComponent
 Inherited
getBounds(targetCoordinateSpace:DisplayObject):Rectangle
Возвращает прямоугольник, определяющий область экранного объекта, которая относится к системе координат объекта targetCoordinateSpace.
DisplayObject
 Inherited
Возвращает экземпляр дочернего экранного объекта, существующий в заданной позиции индекса.
DisplayObjectContainer
 Inherited
Возвращает экземпляр дочернего экранного объекта с заданным именем.
DisplayObjectContainer
 Inherited
Возвращает позицию индекса для дочернего экземпляра DisplayObject.
DisplayObjectContainer
 Inherited
Возвращает объект, который в настоящее время имеет фокус.
UIComponent
 Inherited
Возвращает массив объектов, расположенных ниже заданной позиции и являющихся дочерними объектами любого уровня для данного экземпляра DisplayObjectContainer.
DisplayObjectContainer
 Inherited
getRect(targetCoordinateSpace:DisplayObject):Rectangle
Возвращает прямоугольник, определяющий границу экранного объекта по системе координат, заданной параметром targetCoordinateSpace, за исключением линий фигур.
DisplayObject
 Inherited
Возвращает свойство style, установленное в последовательности для поиска стилей компонента.
UIComponent
  
[статические] Возвращает карту стилей по умолчанию для текущего компонента.
Slider
 Inherited
Преобразует объект Point из координат рабочей области (глобальных) в координаты экранного объекта (локальные).
DisplayObject
 Inherited
Преобразует двумерный объект Point из координат рабочей области (глобальных) в координаты экранного трехмерного объекта (локальные).
DisplayObject
 Inherited
Проверяет наличие у объекта EventDispatcher прослушивателей событий, которые зарегистрированы для получения уведомлений о событиях определенного типа.
EventDispatcher
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Оценивает экранный объект, чтобы определить, перекрывает ли он экранный объект obj или пересекается с ним.
DisplayObject
 Inherited
hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean
Вычисляет экранный объект, чтобы определить, перекрывает ли он точку, заданную координатами x и y, или пересекает ее.
DisplayObject
 Inherited
invalidate(property:String, callLater:Boolean = true):void
Помечает свойство как недопустимое и обновляет компонент в следующем кадре, если не указано иное.
UIComponent
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Преобразует трехмерный объект point из координат трехмерного экранного объекта (локальных) в двухмерный объект point с координатами рабочей области (глобальными).
DisplayObject
 Inherited
Преобразует объект point из координат экранного объекта (локальных) в координаты рабочей области (глобальные).
DisplayObject
 Inherited
[статические] Объединяет стили из нескольких классов в одном объекте.
UIComponent
 Inherited
Перемещает компонент в указанное положение в пределах его родительского компонента.
UIComponent
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Удаляет заданный дочерний объект DisplayObject из списка потомков экземпляра DisplayObjectContainer.
DisplayObjectContainer
 Inherited
Удаляет дочерний DisplayObject из заданной позиции индекса в списке потомков DisplayObjectContainer.
DisplayObjectContainer
 Inherited
removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void
Удаляет прослушиватель из объекта EventDispatcher.
EventDispatcher
 Inherited
Изменяет положение существующего потомка в DisplayObjectContainer.
DisplayObjectContainer
 Inherited
Задает фокус на этот компонент.
UIComponent
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
  
setSize(width:Number, height:Number):void
Задает указанную высоту и ширину компонента.
Slider
 Inherited
setStyle(style:String, value:Object):void
Задает свойство style для экземпляра компонента.
UIComponent
 Inherited
startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void
Позволяет пользователю перетаскивать заданный спрайт (растровый графический объект, легко перемещаемый по экрану).
Sprite
 Inherited
Завершает метод startDrag().
Sprite
 Inherited
Меняет местами (в порядке "от начала к концу") два заданных дочерних объекта.
DisplayObjectContainer
 Inherited
swapChildrenAt(index1:int, index2:int):void
Меняет местами (в порядке "от начала к концу") дочерние объекты, расположенные в двух заданных позициях индекса в списке потомков.
DisplayObjectContainer
 Inherited
Возвращает строковое представление заданного объекта.
Object
 Inherited
Проверяет и обновляет свойства и макет этого объекта, а также перерисовывает его при необходимости.
UIComponent
 Inherited
Возвращает элементарное значение заданного объекта.
Object
 Inherited
Проверяет, зарегистрирован ли прослушиватель событий в объекте EventDispatcher или в любом из его предков для получения уведомлений о событиях определенного типа.
EventDispatcher
Защищенные методы
 МетодОпределено
 Inherited
Возвращает указанный стиль для компонента, учитывая все стили, заданные на глобальном уровне, уровне компонентов и уровне экземпляров.
UIComponent
События
 Событие Сводка Определено
 Inherited[многоадресное событие] Отправляется, когда проигрыватель Flash Player перемещается в фокус операционной системы и становится активным.EventDispatcher
 InheritedОтправляется, когда экранный объект добавляется в список отображения.DisplayObject
 InheritedОтправляется, когда экранный объект добавляется к списку отображения в рабочей области, либо непосредственно, либо путем добавления поддерева, содержащего экранный объект.DisplayObject
  Отправляется при изменении значения компонента Slider в результате действий с мышью или клавиатурой.Slider
 InheritedОтправляется, когда пользователь выбирает команду "Удалить" в контекстном меню текста.InteractiveObject
 InheritedОтправляется, когда пользователь нажимает и отпускает главную кнопку на указывающем устройстве над одним и тем же объектом InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Копировать", или выбирает команду "Копировать" из контекстного меню.InteractiveObject
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Вырезать", или выбирает команду "Вырезать" из контекстного меню.InteractiveObject
 Inherited[многоадресное событие] Отправляется, когда проигрыватель Flash Player покидает фокус операционной системы и становится неактивным.EventDispatcher
 InheritedОтправляется, когда пользователь дважды нажимает и отпускает главную кнопку на указывающем устройстве над одним и тем же объектом InteractiveObject, а флаг doubleClickEnabled для этого объекта имеет значение true.InteractiveObject
 Inherited[многоадресное событие] Отправляется, когда точка воспроизведения переходит в новый кадр.DisplayObject
 Inherited[многоадресное событие] Отправляется, когда точка воспроизведения покидает текущий кадр.DisplayObject
 InheritedОтправляется, когда экранный объект перемещается в фокус.InteractiveObject
 InheritedОтправляется, когда экранный объект покидает фокус.InteractiveObject
 Inherited[многоадресное событие] Отправляется после завершения работы конструкторов экранных объектов кадра до выполнения сценариев кадра.DisplayObject
 InheritedОтправляется, когда видимый компонент становится невидимым.UIComponent
 InheritedОтправляется, когда пользователь нажимает клавишу.InteractiveObject
 InheritedОтправляется, когда пользователь пытается изменить фокус с помощью клавиатуры.InteractiveObject
 InheritedОтправляется, когда пользователь отпускает клавишу.InteractiveObject
 InheritedОтправляется, когда пользователь нажимает кнопку на указывающем устройстве над экземпляром InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется, когда пользователь пытается изменить фокус с помощью указывающего устройства.InteractiveObject
 InheritedОтправляется, когда пользователь перемещает указывающее устройство в момент, когда курсор находится над объектом InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь перемещает указывающее устройство от экземпляра InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь наводит указывающее устройству на экземпляр InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется, когда пользователь отпускает кнопку на указывающем устройстве над экземпляром InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется, когда пользователь вращает колесико мыши над экземпляром InteractiveObject в окне проигрывателя Flash Player.InteractiveObject
 InheritedОтправляется при перемещении компонента.UIComponent
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Вставить", или выбирает команду "Вставить" из контекстного меню.InteractiveObject
 InheritedОтправляется перед удалением экранного объекта из списка отображения.DisplayObject
 InheritedОтправляется перед удалением экранного объекта из списка отображения, либо непосредственно, либо путем удаления поддерева, содержащего экранный объект.DisplayObject
 Inherited[многоадресное событие] Отправляется перед обновлением и визуализацией списка отображения.DisplayObject
 InheritedОтправляется при изменении размеров компонента.UIComponent
 InheritedОтправляется, когда пользователь перемещает указывающее устройство от экземпляра InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь наводит указывающее устройство на экземпляр InteractiveObject.InteractiveObject
 InheritedОтправляется, когда пользователь активирует комбинацию клавиш ускорения, используемую на данной платформе для операции "Выделить все", или выбирает команду "Выделить все" из контекстного меню.InteractiveObject
 InheritedОтправляется, когда невидимый компонент становится видимым.UIComponent
 InheritedОтправляется, когда изменяется значение свойства tabChildren объекта.InteractiveObject
 InheritedОтправляется при изменении флага tabEnabled объекта.InteractiveObject
 InheritedОтправляется, когда изменяется значение свойства tabIndex объекта.InteractiveObject
  Отправляется, когда ползунок нажимается, а затем перемещается с помощью мыши.Slider
  Отправляется, когда нажимается ползунок.Slider
  Отправляется, когда ползунок нажимается и отпускается.Slider
Стили
 Стиль Описание Определено
 InheritedТип: flash.text.TextFormat
Объект TextFormat, который используется для визуализации метки компонента, когда кнопка отключена.
UIComponent
 InheritedТип: Number Формат: Length
Заполнитель, отделяющий внешние границы компонента от внешних краев индикатора фокуса, в пикселах.
UIComponent
 InheritedТип: Class
Обложка, используемая для показа индикаторов фокуса.
UIComponent
  
sliderTrackDisabledSkin
Тип: Class
Обложка для отключенной дорожки в компоненте Slider. Значение по умолчанию SliderTrack_disabledSkin.
Slider
  
sliderTrackSkin
Тип: Class
Обложка для дорожки в компоненте Slider. Значение по умолчанию SliderTrack_skin.
Slider
 InheritedТип: flash.text.TextFormat
Объект TextFormat, используемый для визуализации метки компонента.
UIComponent
  
thumbDisabledSkin
Тип: Class
Обложка, используемая для указания отключенного состояния бегунка. Значение по умолчанию SliderThumb_disabledSkin.
Slider
  
thumbDownSkin
Тип: Class
Имя класса, используемого в качестве обложки для бегунка полосы прокрутки при нажатии на бегунок. Значение по умолчанию SliderThumb_downSkin.
Slider
  
thumbOverSkin
Тип: Class
Имя класса, используемого в качестве обложки для бегунка полосы прокрутки, когда курсор находится над бегунком. Значение по умолчанию SliderThumb_overSkin.
Slider
  
thumbUpSkin
Тип: Class
Имя класса, используемого в качестве обложки для бегунка полосы прокрутки. Значение по умолчанию SliderThumb_upSkin.
Slider
  
tickSkin
Тип: Class
Обложка для контрольных меток в компоненте Slider. Значение по умолчанию SliderTick_skin.
Slider
Сведения о свойстве
directionсвойство
direction:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Задает направление ползунка. Допускается выбор значений SliderDirection.HORIZONTAL и SliderDirection.VERTICAL.

Значение по умолчанию SliderDirection.HORIZONTAL



Реализация
    public function get direction():String
    public function set direction(value:String):void

См. также


Пример
В следующем примере для переключения направления ползунка используется флажок:
import fl.controls.CheckBox;
import fl.controls.Slider;
import fl.controls.SliderDirection;

var s:Slider = new Slider();
s.move(25,110);
addChild(s);

var cb:CheckBox = new CheckBox();
cb.move(10,130);
cb.label = "Vertical Slider";
cb.addEventListener(Event.CHANGE, switchSliderDirection);
addChild(cb);

function switchSliderDirection(e:Event):void {
    if(s.direction == SliderDirection.HORIZONTAL) {
        s.direction = SliderDirection.VERTICAL;
    }
    else {
        s.direction = SliderDirection.HORIZONTAL;
    }
}
enabledсвойство 
enabled:Boolean  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Определяет или задает значение, указывающее, поддерживает ли компонент взаимодействие с пользователем. Значение true указывает, что компонент поддерживает взаимодействие с пользователем; значение false указывает на то, что оно не поддерживает его.

Если присвоить свойству enabled значение false, цвет контейнера становится тусклым, а данные, вводимые пользователем, блокируются (за исключением компонентов Label и ProgressBar).

Значение по умолчанию true



Реализация
    public function get enabled():Boolean
    public function set enabled(value:Boolean):void
liveDraggingсвойство 
liveDragging:Boolean  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Определяет или задает логическое значение, указывающее, отправляется ли событие SliderEvent.CHANGE непрерывно, когда пользователь перетаскивает ползунок. Если свойству liveDragging присвоено значение false, событие SliderEvent.CHANGE отправляется, когда пользователь отпускает ползунок.

Значение по умолчанию false



Реализация
    public function get liveDragging():Boolean

Пример
В следующем примере показано, как при присвоении свойству liveDragging значения true ползунок отправляет событие change при перетаскивании ползунка:
import fl.controls.Slider;
import fl.events.SliderEvent;

var s:Slider = new Slider();
s.move(10,10);
s.liveDragging = true;
s.addEventListener(SliderEvent.CHANGE, announceChange);
addChild(s);

function announceChange(e:SliderEvent):void {
    trace("Slider value is now: " + e.target.value);
}
maximumсвойство 
maximum:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Максимальное значение, допустимое для экземпляра компонента Slider.

Значение по умолчанию 10



Реализация
    public function get maximum():Number
    public function set maximum(value:Number):void

См. также

minimumсвойство 
minimum:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Минимальное значение, допустимое для экземпляра компонента Slider.

Значение по умолчанию 0



Реализация
    public function get minimum():Number
    public function set minimum(value:Number):void

См. также

snapIntervalсвойство 
snapInterval:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Определяет или задает значение, на которое увеличивается или уменьшается значение при перемещении ползунка пользователем.

Например, если этому свойству присвоено значение 2, значение minimum равно 0, а значение maximum равно 10, положение бегунка всегда будет указывать на метки 0, 2, 4, 6, 8 или 10. Если свойству присвоено значение 0, ползунок равномерно перемещается между значениями minimum и maximum.

Значение по умолчанию 0



Реализация
    public function get snapInterval():Number
    public function set snapInterval(value:Number):void

См. также


Пример
В следующем примере создается новый экземпляр Slider, а затем задаются свойства snapInterval и tickInterval:

import fl.controls.Slider;

var mySlider:Slider = new Slider();
mySlider.minimum = 10;
mySlider.maximum = 100;
mySlider.liveDragging = true;
mySlider.snapInterval = 5;
mySlider.tickInterval = mySlider.snapInterval;
mySlider.move(10, 10);
addChild(mySlider);
В следующем примере показан метод принудительной привязки ползунка к значению, делимому на 10, при перетаскивании:
import fl.controls.Slider;

var s:Slider = new Slider();
s.move(10,10);
s.setSize(300,50);
s.maximum = 100;
s.minimum = 0;
s.snapInterval = 10;
addChild(s);
tickIntervalсвойство 
tickInterval:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Промежутки между контрольными метками относительно максимального значения компонента. На компоненте Slider отображаются контрольные метки всякий раз, когда пользователь присваивает свойству tickInterval значение, отличное от нуля.

Значение по умолчанию 0



Реализация
    public function get tickInterval():Number
    public function set tickInterval(value:Number):void

См. также


Пример
В следующем примере показано, как показать контрольные метки над ползунком:
import fl.controls.Slider;

var s:Slider = new Slider();
s.move(10,10);
s.setSize(300,50);
s.maximum = 100;
s.minimum = 0;
s.tickInterval = 5;
addChild(s);
valueсвойство 
value:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Определяет или задает текущее значение компонента Slider. Это значение определяется положением ползунка между минимальным и максимальным значением.

Значение по умолчанию 0



Реализация
    public function get value():Number
    public function set value(value:Number):void

См. также

Сведения о конструкторе
Slider()Конструктор
public function Slider()

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Создает новый экземпляр компонента Slider.

Сведения о методе
getStyleDefinition()метод
public static function getStyleDefinition():Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Возвращает карту стилей по умолчанию для текущего компонента. Карта стилей содержит тип, который подходит для компонента в зависимости от стиля, используемого компонентом. Например, стиль disabledTextFormat содержит значение null или объект TextFormat. Вы можете воспользоваться этими стилями и вызвать метод setStyle() по отношению к текущему компоненту. Следующий код переопределяет стиль disabledTextFormat, выбранный по умолчанию для указанного компонента:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Возвращает
Object — Объект стилей по умолчанию.

См. также


Пример

В следующем примере создается обозреватель стилей для нескольких классов компонентов:
import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}
setSize()метод 
override public function setSize(width:Number, height:Number):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Задает указанную высоту и ширину компонента.

Параметры

width:Number — Ширина компонента в пикселах.
 
height:Number — Высота компонента в пикселах.

Сведения о событии
change Событие
Тип объекта события: fl.events.SliderEvent
свойство SliderEvent.type = fl.events.SliderEvent.CHANGE

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Отправляется при изменении значения компонента Slider в результате действий с мышью или клавиатурой. Если свойству liveDragging присвоено значение true, событие отправляется непрерывно по мере того, как пользователь перемещает бегунок. Если свойству liveDragging присвоено значение false, событие отправляется после того, как пользователь отпускает ползунок.

Задает значение свойства type для объекта события change.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
clickTargetУказывает, нажата ли дорожка или ползунок.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
keyCodeЕсли событие было вызвано нажатием клавиши, возвращается код нажатой клавиши.
targetОбъект, отправивший событие. Адресат не всегда является объектом, выполняющим прослушивание события. Воспользуйтесь свойством currentTarget для доступа к объекту, прослушивающему событие.
triggerEventТип устройства, запустившего событие. Значение InteractionInputType.MOUSE указывает на то, что источником ввода служит мышь; значение InteractionInputType.KEYBOARD говорит о том, что данные вводились с клавиатуры.
valueЗначение ползунка после события.

См. также

thumbDrag Событие  
Тип объекта события: fl.events.SliderEvent
свойство SliderEvent.type = fl.events.SliderEvent.THUMB_DRAG

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Отправляется, когда ползунок нажимается, а затем перемещается с помощью мыши. Этому событию всегда предшествует событие thumbPress.

Задает значение свойства type для объекта события thumbDrag.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
clickTargetУказывает, нажата ли дорожка или ползунок.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
keyCodeЕсли событие было вызвано нажатием клавиши, возвращается код нажатой клавиши.
targetОбъект, отправивший событие. Адресат не всегда является объектом, выполняющим прослушивание события. Воспользуйтесь свойством currentTarget для доступа к объекту, прослушивающему событие.
triggerEventТип устройства, запустившего событие. Значение InteractionInputType.MOUSE указывает на то, что источником ввода служит мышь; значение InteractionInputType.KEYBOARD говорит о том, что данные вводились с клавиатуры.
valueЗначение ползунка после события.

Пример

В следующем примере создаются новые экземпляры компонентов Label и Slider и выполняется прослушивание события thumbDrag ползунка:

import fl.controls.Label;
import fl.controls.Slider;
import fl.events.SliderEvent;

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "";
myLabel.move(10, 10);
addChild(myLabel);

var mySlider:Slider = new Slider();
mySlider.addEventListener(SliderEvent.THUMB_DRAG, thumbDragHandler);
mySlider.move(myLabel.x, myLabel.y + myLabel.height);
addChild(mySlider);

function thumbDragHandler(event:SliderEvent):void {
    myLabel.text = event.type + ": " + event.value;
}

См. также

thumbPress Событие  
Тип объекта события: fl.events.SliderEvent
свойство SliderEvent.type = fl.events.SliderEvent.THUMB_PRESS

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Отправляется, когда нажимается ползунок.

Задает значение свойства type для объекта события thumbPress.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
clickTargetУказывает, нажата ли дорожка или ползунок.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
keyCodeЕсли событие было вызвано нажатием клавиши, возвращается код нажатой клавиши.
targetОбъект, отправивший событие. Адресат не всегда является объектом, выполняющим прослушивание события. Воспользуйтесь свойством currentTarget для доступа к объекту, прослушивающему событие.
triggerEventТип устройства, запустившего событие. Значение InteractionInputType.MOUSE указывает на то, что источником ввода служит мышь; значение InteractionInputType.KEYBOARD говорит о том, что данные вводились с клавиатуры.
valueЗначение ползунка после события.

См. также

thumbRelease Событие  
Тип объекта события: fl.events.SliderEvent
свойство SliderEvent.type = fl.events.SliderEvent.THUMB_RELEASE

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Отправляется, когда ползунок нажимается и отпускается.

Задает значение свойства type для объекта события thumbRelease.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
clickTargetУказывает, нажата ли дорожка или ползунок.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
keyCodeЕсли событие было вызвано нажатием клавиши, возвращается код нажатой клавиши.
targetОбъект, отправивший событие. Адресат не всегда является объектом, выполняющим прослушивание события. Воспользуйтесь свойством currentTarget для доступа к объекту, прослушивающему событие.
triggerEventТип устройства, запустившего событие. Значение InteractionInputType.MOUSE указывает на то, что источником ввода служит мышь; значение InteractionInputType.KEYBOARD говорит о том, что данные вводились с клавиатуры.
valueЗначение ползунка после события.

Пример

В следующем примере выполняется прослушивание событий thumbPress и thumbRelease компонента Slider, а также обновляется поставщик данных для компонента List:

import fl.controls.List;
import fl.controls.Slider;
import fl.data.DataProvider;
import fl.events.SliderEvent;

var dp:DataProvider = new DataProvider();

var mySlider:Slider = new Slider();
mySlider.snapInterval = 1;
mySlider.tickInterval = mySlider.snapInterval;
mySlider.addEventListener(SliderEvent.THUMB_PRESS, thumbPressHandler);
mySlider.addEventListener(SliderEvent.THUMB_RELEASE, thumbReleaseHandler);
mySlider.move(10, 10);
addChild(mySlider);

var myList:List = new List();
myList.dataProvider = dp;
myList.move(mySlider.x + mySlider.width + 10, mySlider.y);
addChild(myList);

function thumbPressHandler(event:SliderEvent):void {
    myList.enabled = false;
}

function thumbReleaseHandler(event:SliderEvent):void {
    var sl:Slider = event.currentTarget as Slider;
    var i:uint;
    dp.removeAll();
    for (i = sl.minimum; i <= event.value; i++) {
        dp.addItem({label:"Item " + i, value:i});
    }
    myList.rowCount = myList.length;
    myList.enabled = true;
}

См. также

Примеры Как пользоваться примерами
SliderExample.as

Это пример прослушивания событий компонента Slider.
  1. Перетащите компонент Slider в рабочую область и назовите его slider.
  2. Перетащите компонент Label в рабочую область и назовите его sliderLabel.
  3. Сохраните этот код под именем SliderExample.as в том же каталоге, где и FLA-файл.
  4. Присвойте параметру DocumentClass в FLA-файле значение SliderExample.
package
{
    import flash.display.Sprite;
    import fl.events.SliderEvent;
    
    public class SliderExample extends Sprite    
    {
        public function SliderExample() {
            configureListeners();
        }
        private function configureListeners():void {
            slider.addEventListener(SliderEvent.CHANGE, sliderChanged);
            slider.addEventListener(SliderEvent.THUMB_DRAG, sliderDrag);
            slider.addEventListener(SliderEvent.THUMB_PRESS, sliderPress);            
            slider.addEventListener(SliderEvent.THUMB_RELEASE, sliderRelease);
        }
        private function sliderDrag(e:SliderEvent):void {
            trace("Slider dragging: " + e.target.value);
            sliderLabel.text = "Slider dragging: " + e.target.value;    
        }
        private function sliderPress(e:SliderEvent):void {
            sliderLabel.text = "Slider pressed";    
        }
        private function sliderRelease(e:SliderEvent):void {
            sliderLabel.text = "Slider released";    
        }
        private function sliderChanged(e:SliderEvent):void {
            sliderLabel.text = "Slider changed: " + e.target.value;    
        }
    }
}