Главная / Action Script 3
Пакетflash.printing
Классpublic class PrintJobOptions
НаследованиеPrintJobOptions Inheritance Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Класс PrintJobOptions содержит свойства для применения с параметром параметры метода PrintJob.addPage(). Дополнительную информацию о addPage() см. в классе PrintJob.

См. также

PrintJob
PrintJob.addPage()
Задачи проигрывателя Flash Player или AIR и системная печать


Общедоступные свойства
 СвойствоОпределено
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
  printAsBitmap : Boolean = false
Определяет режим печати содержимого по заданию печати: как растровое или как векторное изображение.
PrintJobOptions
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
Общедоступные методы
 МетодОпределено
  
PrintJobOptions(printAsBitmap:Boolean = false)
Создает новый объект PrintJobOptions.
PrintJobOptions
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
 Inherited
Возвращает строковое представление заданного объекта.
Object
 Inherited
Возвращает элементарное значение заданного объекта.
Object
Сведения о свойстве
printAsBitmapсвойство
public var printAsBitmap:Boolean = false

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Определяет режим печати содержимого по заданию печати: как растровое или как векторное изображение. По умолчанию для печати в векторном формате задано значение false.

Если распечатываемое содержимое содержит растровое изображение, установите для свойства printAsBitmap значение true, чтобы можно было включить альфа-прозрачность и какие-либо цветовые эффекты. Если в содержимом нет растровых изображений, необходимо распечатывать его в высококачественном векторном формате (формат по умолчанию).

Например, чтобы распечатать содержимое как растровое изображение, используйте следующий синтаксис:

         var options:PrintJobOptions = new PrintJobOptions();
         options.printAsBitmap = true;
         myPrintJob.addPage(mySprite, null, options);
         


Пример
В следующем примере вначале выполняется загрузка изображения, помещение его в прямоугольный кадр, а затем печать его как растрового изображения.
  1. Конструктор загружает изображение (image.jpg), используя объекты Loader и URLRequest. Он также проверяет, не произошло ли ошибок во время загрузки. Здесь предполагается, что файл находится в том же каталоге, что и SWF-файл. SWF-файл должен быть откомпилирован с установленным для параметра Local Playback Secuirty режимом Access Local Files Only.
  2. При загрузке изображения (завершении события) вызывается метод completeHandler().
  3. Метод completeHandler() создает объект BitmapData и загружает в него изображение (растровое). В объекте Sprite рисуется прямоугольник (кадр) и используется метод beginBitmapFill() для заполнения его изображением (объект BitmapData). Объект Matrix также используется для масштабирования изображения и заполнения им прямоугольника. (Обратите внимание на то, что изображение при этом искажается. Этот объект используется в данном примере, чтобы обеспечить гарантированное заполнение прямоугольника изображением.) Как только заполнение изображением произведено, вызывается метод printPage().
  4. Метод printPage() создает новый экземпляр задания печати и запускает процесс печати, вызывая диалоговое окно "Печать" для пользователя и заполняя значениями свойства задания печати. Метод addPage() содержит подробные сведения о задании печати. Здесь кадр с изображением (объект Sprite) настроен для печати как растровое, а не векторное изображение. Параметры являются экземпляром класса PrintJobOptions, а для его свойства printAsBitmap установлено значение true, чтобы выполнять печать растрового изображения (по умолчанию установлено значение false).

Примечание. Для этого примера определена минимальная обработка ошибок.

package {
    import flash.display.Sprite;
    import flash.display.Loader;
    import flash.display.Bitmap;
    import flash.display.BitmapData;    
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOptions;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.net.URLRequest;
    import flash.geom.Matrix;

    public class printAsBitmapExample extends Sprite {

        private var frame:Sprite = new Sprite();
        private var url:String = "image.jpg";
        private var loader:Loader = new Loader();

        public function printAsBitmapExample() {

           var request:URLRequest = new URLRequest(url);
  
           loader.load(request);
           loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
           loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
        
            var picture:Bitmap = Bitmap(loader.content);
            var bitmap:BitmapData = picture.bitmapData;

            var matrix:Matrix = new Matrix();

            matrix.scale((200 / bitmap.width), (200 / bitmap.height));
            
            frame.graphics.lineStyle(10);
            frame.graphics.beginBitmapFill(bitmap, matrix, true);
            frame.graphics.drawRect(0, 0, 200, 200);
            frame.graphics.endFill();

            addChild(frame);
             
            printPage();    
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load the image: " + url);
        }

        private function printPage ():void {
            var myPrintJob:PrintJob = new PrintJob();
            var options:PrintJobOptions = new PrintJobOptions();
            options.printAsBitmap = true;
            
            myPrintJob.start();
  
            try {
                myPrintJob.addPage(frame, null, options);
            }
            catch(e:Error) {
                trace ("Had problem adding the page to print job: " + e);
            }
 
            try {
            myPrintJob.send();
            }
            catch (e:Error) {
                trace ("Had problem printing: " + e);    
            }
        }
    }
}

Сведения о конструкторе
PrintJobOptions()Конструктор
public function PrintJobOptions(printAsBitmap:Boolean = false)

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Создает новый объект PrintJobOptions. Этот объект передается в параметр options метода PrintJob.addPage().

Параметры
printAsBitmap:Boolean (default = false) — Если установлено true, этот объект распечатывается как растровое изображение. Если установлено false, этот объект распечатывается как векторное изображение.

Если распечатываемое содержимое содержит растровое изображение, установите для свойства printAsBitmap значение true, чтобы можно было включить альфа-прозрачность и какие-либо цветовые эффекты. Если в содержимом нет растровых изображений, пропустите данный параметр, чтобы распечатать содержимое в высококачественном векторном формате (формат по умолчанию).

См. также