Главная / Action Script 3
Пакетflash.text.engine
Классpublic final class ElementFormat
НаследованиеElementFormat Inheritance Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Класс ElementFormat представляет информацию о форматировании, применимую к ContentElement. Используйте класс ElementFormat для создания специального форматирования текста для различных подклассов ContentElement. Свойства класса ElementFormat применяются к шрифтам устройства и встроенным шрифтам.

Объект ElementFormat, примененный к ContentElement в элементе TextBlock, не аннулирует действие TextBlock. После применения объекта ElementFormat к ContentElement для его свойства locked задается значение true. Изменение свойств заблокированного объекта ElementFormat невозможно. Вместо этого необходимо использовать метод clone() для создания разблокированной копии объекта, который можно изменить и присвоить объекту ContentElement.

Посмотреть примеры

См. также

flash.text.engine.ContentElement.elementFormat
Форматирование текста


Общедоступные свойства
 СвойствоОпределено
  alignmentBaseline : String
Указывает, по какой из базовых линий строки, содержащей элемент, выравнивается dominantBaseline, определяя вертикальную позицию элемента в строке.
ElementFormat
  alpha : Number
Дает автору возможность автоматически задавать свойству alpha для всех атомов строки, основанных на формате элемента, указанное значение Number.
ElementFormat
  baselineShift : Number
Указывает смещение базовой линии для элемента, в пикселах.
ElementFormat
  breakOpportunity : String
Возможный разрыв строки в тексте.
ElementFormat
  color : uint
Указывает цвет текста.
ElementFormat
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
  digitCase : String
Регистр цифр в тексте.
ElementFormat
  digitWidth : String
Ширина цифр в тексте.
ElementFormat
  dominantBaseline : String
Указывает, какая из базовых линий элемента выравнивается по alignmentBaseline для определения вертикальной позиции элемента в строке.
ElementFormat
  fontDescription : FontDescription
Объект, включающий свойства, необходимые для описания шрифта.
ElementFormat
  fontSize : Number
Размер текста в пикселах.
ElementFormat
  kerning : String
Кернинг текста.
ElementFormat
  ligatureLevel : String
Лигатура в тексте.
ElementFormat
  locale : String
Локаль текста.
ElementFormat
  locked : Boolean
Обозначает, заблокирован ли объект ElementFormat.
ElementFormat
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
  textRotation : String
Задает вращение, применяемое к отдельным глифам символа.
ElementFormat
  trackingLeft : Number
Трекинг или ручной кернинг, применяемый слева от каждого глифа, в пикселах.
ElementFormat
  trackingRight : Number
Трекинг или ручной кернинг, применяемый справа от каждого глифа, в пикселах.
ElementFormat
  typographicCase : String
Регистр текста.
ElementFormat
Общедоступные методы
 МетодОпределено
  
ElementFormat(fontDescription:FontDescription = null, fontSize:Number = 12.0, color:uint = 0x000000, alpha:Number = 1.0, textRotation:String = "auto", dominantBaseline:String = "roman", alignmentBaseline:String = "useDominantBaseline", baselineShift:Number = 0.0, kerning:String = "on", trackingRight:Number = 0.0, trackingLeft:Number = 0.0, locale:String = "en", breakOpportunity:String = "auto", digitCase:String = "default", digitWidth:String = "default", ligatureLevel:String = "common", typographicCase:String = "default")
Создает объект ElementFormat.
ElementFormat
  
Создание разблокированной клонированной копии объекта ElementFormat.
ElementFormat
  
Возвращает объект FontMetrics со свойствами, описывающими emBox, положение зачеркивания, толщину зачеркивания, положение подчеркивания, толщину подчеркивания и шрифта, заданного fontDescription и fontSize.
ElementFormat
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
 Inherited
Возвращает строковое представление заданного объекта.
Object
 Inherited
Возвращает элементарное значение заданного объекта.
Object
Сведения о свойстве
alignmentBaselineсвойство
alignmentBaseline:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Указывает, по какой из базовых линий строки, содержащей элемент, выравнивается dominantBaseline, определяя вертикальную позицию элемента в строке. Используйте константы flash.text.engine.TextBaseline для этого свойства.

Базовые линии определяются самым большим элементом в строке, если не заданы TextBlock.baselineFontDescription и TextBlock.baselineFontSize для изменения этой логики.

Значение по умолчанию — flash.text.engine.TextBaseline.USE_DOMINANT_BASELINE.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
TextBaseline.ROMANdominantBaseline выравнивается по латинской базовой линии строки.
TextBaseline.ASCENTdominantBaseline выравнивается по надстрочной базовой линии строки.
TextBaseline.DESCENTdominantBaseline выравнивается по подстрочной базовой линии строки.
TextBaseline.IDEOGRAPHIC_TOPdominantBaseline выравнивается по идеографической верхней базовой линии строки.
TextBaseline.IDEOGRAPHIC_CENTERdominantBaseline выравнивается по идеографической центральной базовой линии строки.
TextBaseline.IDEOGRAPHIC_BOTTOMdominantBaseline выравнивается по идеографической нижней базовой линии строки.
TextBaseline.USE_DOMINANT_BASELINEdominantBaseline выравнивается по той же базовой линии строки.

ПодклассРезультат определения свойства
GraphicElementЗадает базовую линию выравнивания строки, по которой выравнивается dominantBaseline графического элемента.
GroupElementНе оказывает влияния.
TextElementЗадает базовую линию выравнивания строки, по которой выравнивается dominantBaseline текстового элемента.



Реализация
    public function get alignmentBaseline():String
    public function set alignmentBaseline(value:String):void

Выдает
ArgumentError — Если задано значение, не являющееся элементом flash.text.engine.TextBaseline.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

alphaсвойство 
alpha:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Дает автору возможность автоматически задавать свойству alpha для всех атомов строки, основанных на формате элемента, указанное значение Number.

Указывает значение альфа-прозрачности заданного объекта. Допустимые значения находятся в диапазоне 0 (полностью прозрачный) — 1 (полностью непрозрачный). Значение по умолчанию 1. Экранные объекты, для которых значение alpha равно 0, являются активными, несмотря на невидимость.

Значение по умолчанию — 1,0.

ПодклассРезультат определения свойства
GraphicElementПрименяет заданное значение альфа-канала к графическому элементу. Мультипликативно объединяется с любым значением альфа-канала, заданным в самом графическом объекте DisplayObject или в TextLine.
GroupElementНе оказывает влияния.
TextElementПрименяет заданное значение альфа-канала к текстовому элементу. Мультипликативно объединяется с любым значением альфа-канала, заданным в TextLine.



Реализация
    public function get alpha():Number
    public function set alpha(value:Number):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

baselineShiftсвойство 
baselineShift:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Указывает смещение базовой линии для элемента, в пикселах.

Элемент смещается с dominantBaseline на это расстояние. Сдвиг добавляется к положение по оси у членов элемента, поэтому в невращаемом тексте положительное смещение базовой линии сдвигает элемент вниз, а отрицательное — вверх.

Значение по умолчанию 0,0, что указывает на отсутствие смещения.

ПодклассРезультат определения свойства
GraphicElementСмещает графический элемент с базовой линии.
GroupElementНе оказывает влияния.
TextElementСмещает текстовый элемент с базовой линии.



Реализация
    public function get baselineShift():Number
    public function set baselineShift(value:Number):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

breakOpportunityсвойство 
breakOpportunity:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Возможный разрыв строки в тексте. Это свойство определяет, какие символы могут использоваться для разрыва, когда обтекающий текст разбивается на несколько строк. Используйте константы flash.text.engine.BreakOpportunity для этого свойства.

Значение по умолчанию — flash.text.engine.BreakOpportunity.AUTO.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
BreakOpportunity.AUTOВозможные разрывы строк определяются в соответствии со стандартными свойствами символов Юникод, например разрыв между словами и после дефиса.
BreakOpportunity.ANYЛюбой символ в объекте ContentElement рассматривается как возможность разрыва строки. Это значение обычно используется, когда латинский текст встраивается с восточно-азиатский текст и желательны разрывы строк в середине слов.
BreakOpportunity.NONEНи один из символов диапазона не рассматривается как возможность разрыва строки.
BreakOpportunity.ALLВсе символы диапазона рассматриваются как возможность разрыва строки. Полезно для создания таких эффектов, как текст вдоль кривой.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementОпределяет возможность разрыва строки между смежными текстовыми элементами в группе. Если elementFormat группы имеет значение null, используется формат первого из смежных элементов.
TextElementОпределяет возможность разрыва строки между символами в текстовом элементе.



Реализация
    public function get breakOpportunity():String
    public function set breakOpportunity(value:String):void

Выдает
ArgumentError — Если заданное значение не является членом flash.text.engine.BreakOpportunity.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

colorсвойство 
color:uint  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Указывает цвет текста. Целое число, содержащее три 8-разрядных компонента RGB; например, 0xFF0000 — это красный, 0x00FF00 — это зеленый.

Значение по умолчанию — 0x000000, то есть, проигрыватель Flash Player использует черный цвет.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementЗадает цвет текста.



Реализация
    public function get color():uint
    public function set color(value:uint):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).
digitCaseсвойство 
digitCase:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Регистр цифр в тексте. Регистр цифр влияет на стиль и расположение групп числовых символов. Используйте константы flash.text.engine.DigitCase для этого свойства.

Значение по умолчанию — flash.text.engine.DigitCase.DEFAULT.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
DigitCase.DEFAULTПрименяет к тексту регистр цифр по умолчанию.
DigitCase.LININGПрименяет к тексту маюскульный регистр цифр.
DigitCase.OLD_STYLEПрименяет к тексту минускульный регистр цифр.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementОпределяет регистр цифр, используемый для текста в элементе.



Реализация
    public function get digitCase():String
    public function set digitCase(value:String):void

Выдает
ArgumentError — Если задано значение, не являющееся элементом flash.text.engine.DigitCase.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

digitWidthсвойство 
digitWidth:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Ширина цифр в тексте. Используйте константы flash.text.engine.DigitWidth для этого свойства.

Значение по умолчанию — flash.text.engine.DigitWidth.DEFAULT.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
DigitWidth.DEFAULTПрименяет к тексту ширину цифр по умолчанию.
DigitWidth.PROPORTIONALПрименяет к тексту пропорциональную ширину цифр.
DigitWidth.TABULARПрименяет к тексту табличную ширину цифр.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementОпределяет ширину цифр, используемую для текста в элементе.



Реализация
    public function get digitWidth():String
    public function set digitWidth(value:String):void

Выдает
ArgumentError — Если задано значение, не являющееся элементом flash.text.engine.DigitWidth.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

dominantBaselineсвойство 
dominantBaseline:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Указывает, какая из базовых линий элемента выравнивается по alignmentBaseline для определения вертикальной позиции элемента в строке. Используйте константы flash.text.engine.TextBaseline для этого свойства.

Содержимое элемента определяет базовые линии. В случае с TextElement базовые линии определяются шрифтом и размером кегля. В случае с GraphicElement базовые линии определяются высотой элемента.

Значение по умолчанию — flash.text.engine.TextBaseline.ROMAN.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
TextBaseline.ROMANЛатинская базовая линия элемента выравнивается по alignmentBaseline.
TextBaseline.ASCENTНадстрочная базовая линия элемента выравнивается по alignmentBaseline.
TextBaseline.DESCENTПодстрочная базовая линия элемента выравнивается по alignmentBaseline.
TextBaseline.IDEOGRAPHIC_TOPИдеографическая верхняя базовая линия элемента выравнивается по alignmentBaseline.
TextBaseline.IDEOGRAPHIC_CENTERИдеографическая центральная базовая линия элемента выравнивается по alignmentBaseline.
TextBaseline.IDEOGRAPHIC_BOTTOMИдеографическая нижняя базовая линия элемента выравнивается по alignmentBaseline.

ПодклассРезультат определения свойства
GraphicElementОпределяет, какая из базовых линий графического элемента выравнивается по alignmentBaseline.
GroupElementНе оказывает влияния.
TextElementОпределяет, какая из базовых линий текстового элемента выравнивается по alignmentBaseline.



Реализация
    public function get dominantBaseline():String
    public function set dominantBaseline(value:String):void

Выдает
ArgumentError — Если задано значение, не являющееся элементом flash.text.engine.TextBaseline.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

fontDescriptionсвойство 
fontDescription:FontDescription  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Объект, включающий свойства, необходимые для описания шрифта.

Значением по умолчанию является объект FontDescription, созданный по умолчанию.

Если задается свойство fontDescription, предоставленный объект FontDescription заблокирован: для его свойства locked задано значение true. Изменение заблокированного объекта FontDescription невозможно.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementОпределяет шрифт, используемый для текста в элементе.



Реализация
    public function get fontDescription():FontDescription
    public function set fontDescription(value:FontDescription):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

fontSizeсвойство 
fontSize:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Размер текста в пикселах.

Значение по умолчанию — 12,0.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementОпределяет размер текста элемента в пикселах.



Реализация
    public function get fontSize():Number
    public function set fontSize(value:Number):void

Выдает
ArgumentError — Если задано значение меньше нуля.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).
kerningсвойство 
kerning:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Кернинг текста. Используйте константы flash.text.engine.Kerning для этого свойства. Кернинг регулирует количество пикселов между определенными парами символов с целью улучшения удобочитаемости текста. Кернинг поддерживается для всех шрифтов, имеющих таблицы кернинга.

Значение по умолчанию — flash.text.engine.Kerning.ON.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
Kerning.ONКернинг включен.
Kerning.OFFКернинг выключен.
Kerning.AUTOКернинг включается только для соответствующих символов в восточно-азиатской типографике. Кернинг применяется между двумя символами, если ни один из них не принадлежит к кандзи, хирагана или катакана.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementОпределяет, применяется ли кернинг между смежными текстовыми элементами в группе. Если elementFormat группы имеет значение null, используется формат первого из смежных элементов.
TextElementОпределяет, применяется ли кернинг между символами в текстовом элементе.



Реализация
    public function get kerning():String
    public function set kerning(value:String):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

ligatureLevelсвойство 
ligatureLevel:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Лигатура в тексте. Лигатура возникает, когда две или более литеры объединяются в один глиф. Лигатуры обычно заменяют последовательные символы с общими компонентами, такие как пары букв "fi", "fl" или "ae". Они используются как с латинскими, так и с нелатинскими наборами символов. Используйте константы flash.text.engine.LigatureLevel для этого свойства.

Значение по умолчанию — flash.text.engine.LigatureLevel.COMMON.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
LigatureLevel.NONEЛигатуры не создаются.
LigatureLevel.MINIMUMСоздаются минимальные лигатуры.
LigatureLevel.COMMONСоздаются обычные лигатуры.
LigatureLevel.UNCOMMONСоздаются необычные лигатуры.
LigatureLevel.EXOTICСоздаются экзотические лигатуры.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementОпределяет уровень лигатуры между смежными текстовыми элементами в группе. Если elementFormat группы имеет значение null, используется формат первого из смежных элементов.
TextElementОпределяет уровень лигатуры между символами в текстовом элементе.



Реализация
    public function get ligatureLevel():String
    public function set ligatureLevel(value:String):void

Выдает
ArgumentError — Если задано значение, не являющееся элементом flash.text.engine.LigatureLevel.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

localeсвойство 
locale:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Локаль текста. Управляет преобразованием регистра и формированием. Используются стандартные идентификаторы локали. Например "en", "en_US" и "en-US" относятся к английскому, а "ja" — к японскому.

Значение по умолчанию равно "en".

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementОпределяет преобразования и формирование для текста в элементе.



Реализация
    public function get locale():String
    public function set locale(value:String):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).
lockedсвойство 
locked:Boolean  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5.

Обозначает, заблокирован ли объект ElementFormat. Если задано значение true, изменение объекта ElementFormat невозможно. Вызовите метод ElementFormat.clone() для получения разблокированной копии объекта ElementFormat.



Реализация
    public function get locked():Boolean
    public function set locked(value:Boolean):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

textRotationсвойство 
textRotation:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Задает вращение, применяемое к отдельным глифам символа. Используйте константы flash.text.engine.TextRotation для этого свойства.

Значение по умолчанию — flash.text.engine.TextRotation.AUTO.

Конечный поворот любого глифа является суммой ElementFormat.textRotation, ContentElement.textRotation и TextBlock.lineRotation.

ElementFormat.textRotation обычно применяется для восточно-азиатского текста, где символы должны поворачиваться для правильного отображения в вертикальной раскладке: значение flash.text.engine.TextRotation.AUTO используется в сочетании с TextBlock.lineRotation = flash.text.engine.ROTATE_90.

Определение этого свойства для шрифтов, не содержащих сведений о вертикальной раскладке, может дать нежелательные результаты. Шрифты, содержащие таблицу vmtx или VORG, такие как японский шрифт MS Mincho, работают правильно, так как эти таблицы предоставляют данные, необходимые процессору раскладки. Такие шрифты, как Verdana, не содержащие необходимой информации, работают неправильно.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
TextRotation.ROTATE_0Глифы не поворачиваются.
TextRotation.ROTATE_90Глифы поворачиваются на 90 градусов по часовой стрелке.
TextRotation.ROTATE_180Глифы поворачиваются на 180 градусов.
TextRotation.ROTATE_270Глифы поворачиваются на 270 градусов по часовой стрелке.
TextRotation.AUTOЗадает поворот на 90 градусов против часовой стрелки только для полноширинных и широких глифов, в соответствии со свойствами Юникод для глифа. Обычно это значение используется с восточно-азиатскими текстами, чтобы поворачивать только глифы, требующие поворота. Этот поворот применяется только к вертикальному тексту, чтобы возвращать полноширинным и широким символам вертикальную ориентацию, не затрагивая остальных символов.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementОпределяет поворот глифов в текстовом элементе.



Реализация
    public function get textRotation():String
    public function set textRotation(value:String):void

Выдает
ArgumentError — Если задано значение, не являющееся элементом flash.text.engine.TextRotation.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

trackingLeftсвойство 
trackingLeft:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5.

Трекинг или ручной кернинг, применяемый слева от каждого глифа, в пикселах. Если kerning включен, значение trackingLeft добавляется к значениям в таблице кернинга для шрифта. Если kerning выключен, значение trackingLeft используется в качестве значения ручного кернинга. Поддерживает как положительные, так и отрицательные значения.

Обычно желаемое значение трекинга делится между trackingRight и trackingLeft. В противном случае в тексте со смешанной направленностью у одной двунаправленной границы будет двойной трекинг, а у другой — нулевой.

Значение по умолчанию 0,0.

ПодклассРезультат определения свойства
GraphicElementОпределяет трекинг, применяемый к левой стороне графического элемента.
GroupElementНе оказывает влияния.
TextElementОпределяет трекинг, применяемый к левой стороне символов в текстовом элементе.

Пример:

       //positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingLeft = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingLeft = -1.0;
  



Реализация
    public function get trackingLeft():Number
    public function set trackingLeft(value:Number):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

trackingRightсвойство 
trackingRight:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5.

Трекинг или ручной кернинг, применяемый справа от каждого глифа, в пикселах. Если kerning включен, значение trackingRight добавляется к значениям в таблице кернинга для шрифта. Если kerning выключен, значение trackingRight используется в качестве значения ручного кернинга. Поддерживает как положительные, так и отрицательные значения.

Обычно желаемое значение трекинга делится между trackingRight и trackingLeft. В противном случае в тексте со смешанной направленностью у одной двунаправленной границы будет двойной трекинг, а у другой — нулевой.

Значение по умолчанию 0,0.

ПодклассРезультат определения свойства
GraphicElementОпределяет трекинг, применяемый к правой стороне графического элемента.
GroupElementНе оказывает влияния.
TextElementОпределяет трекинг, применяемый к правой стороне символов в текстовом элементе.

Пример:

       //positive tracking added to kerning
       var ef1:ElementFormat = new ElementFormat();
       ef1.kerning = flash.text.engine.Kerning.ON;
       ef1.trackingRight = 0.5;
         //negative manual kerning
       var ef2:ElementFormat = new ElementFormat();
       ef2.kerning = flash.text.engine.Kerning.OFF;
       ef2.trackingRight = -1.0;
  



Реализация
    public function get trackingRight():Number
    public function set trackingRight(value:Number):void

Выдает
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

typographicCaseсвойство 
typographicCase:String  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Регистр текста. Используйте константы flash.text.engine.TypographicCase для этого свойства.

Значение по умолчанию — flash.text.engine.TypographicCase.DEFAULT.

В качестве значений этого свойства используйте следующие строковые значения:

Строковое значениеОписание
TypographicCase.DEFAULTПрименяет регистр текста по умолчанию.
TypographicCase.TITLEУказывает, что на выходе символы верхнего регистра используют заголовочные глифы.
TypographicCase.CAPSУказывает, что на выходе для символов верхнего регистра корректируются интервалы.
TypographicCase.SMALL_CAPSУказывает, что на выходе символы верхнего регистра используют капительные глифы.
TypographicCase.UPPERCASEУказывает, что на выходе все символы используют глифы верхнего регистра.
TypographicCase.LOWERCASEУказывает, что на выходе все символы используют глифы нижнего регистра.
TypographicCase.CAPS_AND_SMALL_CAPSУказывает, что на выходе все символы нижнего регистра используют капительные глифы.

ПодклассРезультат определения свойства
GraphicElementНе оказывает влияния.
GroupElementНе оказывает влияния.
TextElementОпределяет регистр текста, используемый для текстового элемента.



Реализация
    public function get typographicCase():String
    public function set typographicCase(value:String):void

Выдает
ArgumentError — Если заданное значение не является членом flash.text.engine.TypographicCase.
 
IllegalOperationError — Если задается после блокирования объекта ElementFormat (для свойства locked задано значение true).

См. также

Сведения о конструкторе
ElementFormat()Конструктор
public function ElementFormat(fontDescription:FontDescription = null, fontSize:Number = 12.0, color:uint = 0x000000, alpha:Number = 1.0, textRotation:String = "auto", dominantBaseline:String = "roman", alignmentBaseline:String = "useDominantBaseline", baselineShift:Number = 0.0, kerning:String = "on", trackingRight:Number = 0.0, trackingLeft:Number = 0.0, locale:String = "en", breakOpportunity:String = "auto", digitCase:String = "default", digitWidth:String = "default", ligatureLevel:String = "common", typographicCase:String = "default")

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Создает объект ElementFormat.

Параметры
fontDescription:FontDescription (default = null) — Объект FontDescription задающий шрифт формата элемента. Значение по умолчанию равно null. Если не выбрано описание шрифта, используется описание по умолчанию.
 
fontSize:Number (default = 12.0) — Размер текста в пикселах.
 
color:uint (default = 0x000000) — Цвет текста. Число, содержащее три 8-разрядных компонента RGB; например, 0xFF0000 — это красный, 0x00FF00 — это зеленый.
 
alpha:Number (default = 1.0) — Свойство alpha применяется ко всем атомам строки на основе формата элемента.
 
textRotation:String (default = "auto") — вращение, применяемое к отдельным образам символа. Используйте константы flash.text.engine.TextRotation для этого свойства.
 
dominantBaseline:String (default = "roman") — Базовая линия, по которой равняются образы символов в тексте. Используйте константы flash.text.engine.TextBaseline для этого свойства.
 
alignmentBaseline:String (default = "useDominantBaseline") — Базовая линия содержащий строки, по которой равняется доминирующая базовая линия. Используйте константы flash.text.engine.TextBaseline для этого свойства.
 
baselineShift:Number (default = 0.0) — Сдвиг базовой линии для текста в пикселах.
 
kerning:String (default = "on") — Кернинг текста. Используйте flash.text.engine.Kerning.
 
trackingRight:Number (default = 0.0) — Трекинг или ручной кернинг, применяемый справа от каждого глифа, в пикселах.
 
trackingLeft:Number (default = 0.0) — Трекинг или ручной кернинг, применяемый слева от каждого глифа, в пикселах.
 
locale:String (default = "en") — Локаль текста.
 
breakOpportunity:String (default = "auto") — Возможный разрыв строки в тексте. Используйте константы flash.text.engine.BreakOpportunity для этого свойства.
 
digitCase:String (default = "default") — Регистр цифр в тексте. Используйте константы flash.text.engine.DigitCase для этого свойства.
 
digitWidth:String (default = "default") — Ширина цифр в тексте. Используйте константы flash.text.engine.DigitWidth для этого свойства.
 
ligatureLevel:String (default = "common") — Лигатура в тексте. Используйте константы flash.text.engine.LigatureLevel для этого свойства.
 
typographicCase:String (default = "default") — Регистр текста. Используйте константы flash.text.engine.TypographicCase для этого свойства.

Выдает
ArgumentError — Заданный fontSize меньше 0.
 
ArgumentError — Заданная локаль FontMetrics не является членом flash.text.engine.TextRotation.
 
ArgumentError — Заданная локаль dominantBaseline не является членом flash.text.engine.TextBaseline.
 
ArgumentError — Заданная локаль alignmentBaseline не является членом flash.text.engine.TextBaseline.
 
ArgumentError — Заданная локаль kerning не является членом flash.text.engine.Kerning.
 
ArgumentError — Заданная локаль breakOpportunity не является членом flash.text.engine.BreakOpportunity.
 
ArgumentError — Заданная локаль digitCase не является членом flash.text.engine.DigitCase.
 
ArgumentError — Заданная локаль digitWidth не является членом flash.text.engine.DigitWidth.
 
ArgumentError — Заданная локаль ligatureLevel не является членом flash.text.engine.LigatureLevel.
 
ArgumentError — Заданная локаль typographicCase не является членом flash.text.engine.TypographicCase.
Сведения о методе
clone()метод
public function clone():ElementFormat

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Создание разблокированной клонированной копии объекта ElementFormat.

Возвращает
ElementFormat — Разблокированная копия объекта ElementFormat.

См. также


Пример

В этом примере создается объект ElementFormat и задается свойство FontSize. Создается новый объект TextElement с использованием ElementFormat (и блокируется таким образом), затем этот объект TextElement используется в качестве содержимого для объекта TextBlock. Из объекта TextBlock создается текстовая строка.

Для изменения объекта ElementFormat сначала проверьте его свойство locked. Если оно имеет значение true, используйте метод clone() для создания разблокированной копии объекта ElementFormat, измените его свойства, затем повторно свяжите новый объект ElementFormat с объектом TextBlock. При повторной разбивке строк новые строки получат новые параметры шрифтов.


package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}
getFontMetrics()метод 
public function getFontMetrics():FontMetrics

Язык версии : ActionScript 3.0
Версии среды выполнения:  10, 1.5

Возвращает объект FontMetrics со свойствами, описывающими emBox, положение зачеркивания, толщину зачеркивания, положение подчеркивания, толщину подчеркивания и шрифта, заданного fontDescription и fontSize.

Возвращает
FontMetrics — Объект FontMetrics, описывающий свойства шрифта, заданного fontDescription.

См. также


Пример

В этом примере показано, как создавать объект ElementFormat и назначать ему FontDescription, а также использовать метод getFontMetrics для отображения метрики выбранного шрифта.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            var fm1:FontMetrics = ef1.getFontMetrics();
            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}
Примеры Как пользоваться примерами
ElementFormatExample.as

В этом примере показано, как создавать два объекта ElementFormat и задавать для них некоторые свойства. Назначается новый ElementFormats объекту TextElement, который назначался в качестве содержимого TextBlock. Изменение ElementFormat объекта TextElement не влияет на текстовые строки, созданные родительским блоком.


package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}