Главная / Action Script 3
ПакетВерхний уровень
Классpublic final dynamic class Date
НаследованиеDate Inheritance Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Класс Date представляет сведения о дате и времени. Экземпляр класса Date представляет определенный момент времени, для которого можно запросить или изменить такие свойства как месяц, день, часы и секунды. Класс Date позволяет извлекать значения даты и времени относительно всемирного времени (среднее время по Гринвичу, которое теперь называется всемирным скоординированным временем или UTC) или местного времени, которое определяется по настройке местного часового пояса в той операционной системе, где запущен Flash Player. Методы класса Date не являются статическими, но применяются только к отдельным объектам Date, указанным при вызове метода. Методы Date.UTC() и Date.parse() представляют собой исключение будучи статическими.

Чтобы воспользоваться классом Date, создайте экземпляр Date с помощью оператора new.

В ActionScript 3.0 добавлено несколько новых свойств средств доступа, которыми можно пользоваться вместо многих методов класса Date, которые выполняют доступ к экземплярам Date или модифицируют их. Также ActionScript 3.0 содержит ряд новых вариантов метода toString(), добавленных в целях соответствия третьему изданию ECMA-262, включая: Date.toLocaleString(), Date.toTimeString(), Date.toLocaleTimeString(), Date.toDateString() и Date.toLocaleDateString().

Чтобы вычислить относительное или прошедшее время, воспользуйтесь методом getTimer() из пакета flash.utils.

Посмотреть примеры

См. также

flash.utils.getTimer()


Общедоступные свойства
 СвойствоОпределено
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
  date : Number
День месяца по местному времени (целое число от 1 до 31), заданный объектом Date.
Date
  dateUTC : Number
День месяца (целое число от 1 до 31) по Гринвичу (UTC) из объекта Date.
Date
  day : Number
[только для чтения] День недели по местному времени (0 — воскресенье, 1 — понедельник, и т.д.), заданный объектом Date.
Date
  dayUTC : Number
[только для чтения] День недели (0 — воскресенье, 1 — понедельник, и т.д.) по Гринвичу (UTC) из объекта Date.
Date
  fullYear : Number
Полный год (четырехзначное число, например, 2000) объекта Date по местному времени.
Date
  fullYearUTC : Number
Четырехзначный год по Гринвичу (UTC) из объекта Date.
Date
  hours : Number
Час дня по местному времени (целое число от 0 до 23) из объекта Date.
Date
  hoursUTC : Number
Час дня (целое число от 0 до 23) по Гринвичу (UTC) из объекта Date.
Date
  milliseconds : Number
Число миллисекунд по местному времени (целое число от 0 до 999) из объекта Date.
Date
  millisecondsUTC : Number
Число миллисекунд (целое число от 0 до 999) по Гринвичу (UTC) из объекта Date.
Date
  minutes : Number
Число минут по местному времени (целое число от 0 до 59) из объекта Date.
Date
  minutesUTC : Number
Число минут (целое число от 0 до 59) по Гринвичу (UTC) из объекта Date.
Date
  month : Number
Месяц (0 — январь, 1 — февраль, и т.д.) объекта Date по местному времени.
Date
  monthUTC : Number
Месяц (от 0 [январь] до 11 [декабрь]) по Гринвичу (UTC) из объекта Date.
Date
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
  seconds : Number
Число секунд по местному времени (целое число от 0 до 59) из объекта Date.
Date
  secondsUTC : Number
Число секунд (целое число от 0 до 59) по Гринвичу (UTC) из объекта Date.
Date
  time : Number
Число миллисекунд с полуночи 1 января 1970 года по Гринвичу для объекта Date.
Date
  timezoneOffset : Number
[только для чтения] Разница в минутах между местным временем компьютера и временем по всемирному скоординированному времени (UTC).
Date
Общедоступные методы
 МетодОпределено
  
Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)
Создает новый объект Date, который содержит заданную дату и время.
Date
  
Возвращает день месяца по местному времени (целое число от 1 до 31), заданный объектом Date.
Date
  
Возвращает день недели по местному времени (0 — воскресенье, 1 — понедельник, и т.д.), заданный объектом Date.
Date
  
Возвращает из объекта Date полный год по местному времени (четырехзначное число, например, 2000).
Date
  
Возвращает из объекта Date час дня по местному времени (целое число от 0 до 23).
Date
  
Возвращает из объекта Date число миллисекунд по местному времени (целое число от 0 до 999).
Date
  
Возвращает из объекта Date число минут по местному времени (целое число от 0 до 59).
Date
  
Возвращает из объекта Date месяц по местному времени (0 — январь, 1 — февраль, и т.д.).
Date
  
Возвращает из объекта Date число секунд по местному времени (целое число от 0 до 59).
Date
  
Возвращает для объекта Date число миллисекунд с полуночи 1 января 1970 года по Гринвичу.
Date
  
Возвращает разницу в минутах между местным временем компьютера и всемирным скоординированным временем (UTC).
Date
  
Возвращает из объекта Date день месяца (целое число от 1 до 31) по Гринвичу (UTC).
Date
  
Возвращает из объекта Date день недели (0 — воскресенье, 1 — понедельник, и т.д.) по Гринвичу (UTC).
Date
  
Возвращает из объекта Date четырехзначный год по Гринвичу (UTC).
Date
  
Возвращает из объекта Date час дня (целое число от 0 до 23) по Гринвичу (UTC).
Date
  
Возвращает из объекта Date число миллисекунд (целое число от 0 до 999) по Гринвичу (UTC).
Date
  
Возвращает из объекта Date число минут (целое число от 0 до 59) по Гринвичу (UTC).
Date
  
Возвращает из объекта Date месяц (от 0 [январь] до 11 [декабрь]) по Гринвичу (UTC).
Date
  
Возвращает из объекта Date число секунд (целое число от 0 до 59) по Гринвичу (UTC).
Date
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
  
[статические] Преобразует строку, представляющую дату, в число, равное количеству миллисекунд с полуночи 1 января 1970 года по Гринвичу (UTC).
Date
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
  
Задает день месяца по местному времени и возвращает новое время в миллисекундах.
Date
  
Задает год по местному времени и возвращает новое время в миллисекундах.
Date
  
setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
Задает час по местному времени и возвращает новое время в миллисекундах.
Date
  
Задает количество миллисекунд по местному времени и возвращает новое время в миллисекундах.
Date
  
setMinutes(minute:Number, second:Number, millisecond:Number):Number
Задает количество минут по местному времени и возвращает новое время в миллисекундах.
Date
  
Задает месяц и (при необходимости) день месяца по местному времени и возвращает новое время в миллисекундах.
Date
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
  
setSeconds(second:Number, millisecond:Number):Number
Задает количество секунд по местному времени и возвращает новое время в миллисекундах.
Date
  
setTime(millisecond:Number):Number
Задает дату в миллисекундах с полуночи 1 января 1970 года и возвращает новое время в миллисекундах.
Date
  
Задает день месяца по Гринвичу (UTC) и возвращает новое время в миллисекундах.
Date
  
Задает год по Гринвичу (UTC) и возвращает новое время в миллисекундах.
Date
  
setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number
Задает час по Гринвичу (UTC) и возвращает новое время в миллисекундах.
Date
  
Задает количество миллисекунд по Гринвичу (UTC) и возвращает новое время в миллисекундах.
Date
  
setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number
Задает количество минут по Гринвичу (UTC) и возвращает новое время в миллисекундах.
Date
  
Задает месяц и (при необходимости) день месяца по Гринвичу (UTC) и возвращает новое время в миллисекундах.
Date
  
setUTCSeconds(second:Number, millisecond:Number):Number
Задает количество секунд и (при необходимости) миллисекунд по Гринвичу (UTC) и возвращает новое время в миллисекундах.
Date
  
Возвращает строковое представление дня и даты без времени или часового пояса.
Date
  
Возвращает строковое представление дня и даты без времени или часового пояса.
Date
  
Возвращает строковое представление дня, даты и времени по местному времени.
Date
  
Возвращает строковое представление времени без дня, даты, года или часового пояса.
Date
  
Возвращает строковое представление дня, даты, времени и часового пояса.
Date
  
Возвращает строковое представление времени и часового пояса без дня и даты.
Date
  
Возвращает строковое представление дня, даты и времени по Гринвичу (UTC).
Date
  
UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number
[статические] Возвращает число миллисекунд от полуночи 1 января 1970 года по Гринвичу до момента, заданного параметрами.
Date
  
Возвращает для объекта Date число миллисекунд с полуночи 1 января 1970 года по Гринвичу.
Date
Сведения о свойстве
dateсвойство
date:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

День месяца по местному времени (целое число от 1 до 31), заданный объектом Date. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get date():Number
    AS3 function set date(value:Number):void

См. также

dateUTCсвойство 
dateUTC:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

День месяца (целое число от 1 до 31) по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get dateUTC():Number
    AS3 function set dateUTC(value:Number):void

См. также

dayсвойство 
day:Number  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

День недели по местному времени (0 — воскресенье, 1 — понедельник, и т.д.), заданный объектом Date. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get day():Number

См. также

dayUTCсвойство 
dayUTC:Number  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

День недели (0 — воскресенье, 1 — понедельник, и т.д.) по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get dayUTC():Number

См. также

fullYearсвойство 
fullYear:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Полный год (четырехзначное число, например 2000) объекта Date по местному времени. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get fullYear():Number
    AS3 function set fullYear(value:Number):void

См. также

fullYearUTCсвойство 
fullYearUTC:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Четырехзначный год по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get fullYearUTC():Number
    AS3 function set fullYearUTC(value:Number):void

См. также

hoursсвойство 
hours:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Час дня по местному времени (целое число от 0 до 23) из объекта Date. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get hours():Number
    AS3 function set hours(value:Number):void

См. также

hoursUTCсвойство 
hoursUTC:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Час дня (целое число от 0 до 23) по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get hoursUTC():Number
    AS3 function set hoursUTC(value:Number):void

См. также

millisecondsсвойство 
milliseconds:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Число миллисекунд по местному времени (целое число от 0 до 999) из объекта Date. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get milliseconds():Number
    AS3 function set milliseconds(value:Number):void

См. также

millisecondsUTCсвойство 
millisecondsUTC:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Число миллисекунд (целое число от 0 до 999) по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get millisecondsUTC():Number
    AS3 function set millisecondsUTC(value:Number):void

См. также

minutesсвойство 
minutes:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Число минут по местному времени (целое число от 0 до 59) из объекта Date. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get minutes():Number
    AS3 function set minutes(value:Number):void

См. также

minutesUTCсвойство 
minutesUTC:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Число минут (целое число от 0 до 59) по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get minutesUTC():Number
    AS3 function set minutesUTC(value:Number):void

См. также

monthсвойство 
month:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Месяц (0 — январь, 1 — февраль и т.д.) объекта Date по местному времени. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get month():Number
    AS3 function set month(value:Number):void

См. также

monthUTCсвойство 
monthUTC:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Месяц (от 0 [январь] до 11 [декабрь]) по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get monthUTC():Number
    AS3 function set monthUTC(value:Number):void

См. также

secondsсвойство 
seconds:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Число секунд по местному времени (целое число от 0 до 59) из объекта Date. Местное время определяется операционной системой, в которой запущен Flash Player.



Реализация
    AS3 function get seconds():Number
    AS3 function set seconds(value:Number):void

См. также

secondsUTCсвойство 
secondsUTC:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Число секунд (целое число от 0 до 59) по всемирному скоординированному времени (UTC) из объекта Date.



Реализация
    AS3 function get secondsUTC():Number
    AS3 function set secondsUTC(value:Number):void

См. также

timeсвойство 
time:Number  [чтение и запись]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Число миллисекунд с полуночи 1 января 1970 года по всемирному скоординированному времени для объекта Date. Воспользуйтесь этим методом, чтобы представить определенный момент во времени при сравнении двух и более объектов Date.



Реализация
    AS3 function get time():Number
    AS3 function set time(value:Number):void

См. также

timezoneOffsetсвойство 
timezoneOffset:Number  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Разница в минутах между местным временем компьютера и временем по всемирному скоординированному времени (UTC). В частности, это значение представляет собой количество минут, которое необходимо добавить к местному времени компьютера, чтобы оно стало равно всемирному. Если время компьютера опережает UTC, значение будет отрицательным.



Реализация
    AS3 function get timezoneOffset():Number

См. также

Сведения о конструкторе
Date()Конструктор
public function Date(yearOrTimevalue:Object, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0)

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Создает новый объект Date, который содержит заданную дату и время.

Конструктор Date() может иметь до 7 параметров (year, month, ..., millisecond), позволяющих указывать дату и время с точностью до миллисекунды. Дата, которую содержит только что созданный объект Date зависит от количества и типа данных переданных аргументов.

Если конструктору класса Date передается строка, дата может быть представлена в разных форматах, но должна включать, по крайней мере, месяц, дату и год. Например, Feb 1 2005 (1 февраля 2005 г.) — это действительное значение в отличие от Feb 2005 (февраль 2005 г.). В списке ниже приведены некоторые действительные форматы:

Параметры
yearOrTimevalue:Object — Если указаны другие параметры, это число выражает год (например, 1965); в противном случае оно представляет собой временное значение. Если данное число относится к году, значения с 0 до 99 указывают на 1900-1999 гг.; в противном случае необходимо указывать все четыре цифры года. Если число представляет собой временное значение (без дополнительно указанных параметров), оно отражает количество миллисекунд до или после 0:00:00 1 января 1970 г. (среднее время по Гринвичу); отрицательные значения отражают время до 0:00:00 1 января 1970 г. (среднее время по Гринвичу), а положительное значение указывает на время после этой даты.
 
month:Number — Целое число от 0 (январь) до 11 (декабрь).
 
date:Number (default = 1) — Целое число от 1 до 31.
 
hour:Number (default = 0) — Целое число от 0 (полночь) до 23 (11 часов вечера).
 
minute:Number (default = 0) — Целое число от 0 до 59.
 
second:Number (default = 0) — Целое число от 0 до 59.
 
millisecond:Number (default = 0) — Целое число от 0 до 999 миллисекунд.

См. также

Сведения о методе
getDate()метод
AS3 function getDate():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает день месяца по местному времени (целое число от 1 до 31), заданный объектом Date. Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — День месяца (1 — 31), который представляет объект Date.

См. также


Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызывается метод getDate(), определяющий день месяца.
package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}
getDay()метод 
AS3 function getDay():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает день недели по местному времени (0 — воскресенье, 1 — понедельник, и т.д.), заданный объектом Date. Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — Числовая версия дня недели (0 — 6), который представляет объект Date.

Пример

В следующем примере создается новый объект Array weekDayLabels с элементами [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] и новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). После этого дважды вызывается метод getDay(), который сначала показывает число месяца в виде цифры 6, а затем показывает день недели с помощью weekDayLabels.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday
getFullYear()метод 
AS3 function getFullYear():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date полный год по местному времени (четырехзначное число, например 2000). Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — Полный год, который представляет объект Date.

Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). После этого вызывается метод getFullYear(), который извлекает четырехзначное обозначение года.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974
getHours()метод 
AS3 function getHours():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает час (целое число от 0 до 23) дня, относящегося к объекту Date, по местному времени. Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — Час (0 — 23) дня, представленного объектом Date.

Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызываются методы getHours() и getMinutes(), которые извлекают часы и минуты в 24-часовом формате. В итоге создается строка localTime, которая присваивается результату вызова функции getUSClockTime(), которая, в свою очередь, снова вызывает методы getHours() и getMinutes(), указывающее время 03:05 PM.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getMilliseconds()метод 
AS3 function getMilliseconds():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date число миллисекунд по местному времени (целое число от 0 до 999). Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — Фрагмент объекта Date с миллисекундами.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getMilliseconds(), который извлекает из объекта Date now число миллисекунд на момент создания

var now:Date = new Date();
trace(now.getMilliseconds());
getMinutes()метод 
AS3 function getMinutes():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date число минут по местному времени (целое число от 0 до 59). Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — Фрагмент объекта Date с минутами.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getMinutes(), который извлекает из объекта Date now число миллисекунд на момент создания

var now:Date = new Date();
trace(now);
trace(now.getMinutes());
getMonth()метод 
AS3 function getMonth():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date месяц по местному времени (0 — январь, 1 — февраль и т.д.). Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — Фрагмент объекта Date с месяцем (0 — 11).

Пример

В следующем примере создается новый объект Array monthLabels с элементами от January до December и новый объект Date now без параметров. Затем дважды вызывается метод getMonth(), который сначала возвращает номер месяца, а затем указывает месяц создания объекта Date now.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);
getSeconds()метод 
AS3 function getSeconds():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date число секунд по местному времени (целое число от 0 до 59). Местное время определяется операционной системой, в которой запущен Flash Player.

Возвращает
Number — Фрагмент объекта Date с секундами (от 0 до 59).

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getSeconds(), который извлекает из объекта Date now число миллисекунд на момент создания

var now:Date = new Date();
trace(now.getSeconds());
getTime()метод 
AS3 function getTime():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает для объекта Date число миллисекунд с полуночи 1 января 1970 года по всемирному скоординированному времени. Воспользуйтесь этим методом, чтобы представить определенный момент во времени при сравнении двух и более объектов Date.

Возвращает
Number — Количество миллисекунд с 1 января 1970 г., выражаемых объектом Date.

Пример

В следующем примере создается новый объект Date mlk с параметрами year (1929), month (0 = январь) и day (15). Затем вызывается метод getTime(), который извлекает количество миллисекунд, прошедших с 1 января 1970 г. Это отрицательное число, поскольку выбран 1929 г.

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

В следующем примере создается новый объект Date now без параметров, а затем используются следующие методы класса DateMath (созданные ниже), добавляющие время в исходный объект Date now, прошедшее с момента его создания:
  • addSeconds(): добавляет 30 секунд к объекту now.
  • addMinutes(): добавляет 30 минут к объекту now.
  • addHours(): добавляет 6 часов к объекту Date now.
  • addHours(): добавляет 30 дней к объекту Date now.
  • addWeeks(): добавляет 4 недели к объекту now.

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}
Примечание. Не забывайте применять метод getTime при выполнении арифметических расчетов с объектом Date, поскольку он продолжает выполняться в високосные годы и не требует наличия набора логических операций с условием "если, то" как в следующем псевдокоде:
 function addMonths(num:Number):void {
 	currentMonth = currentMonth + num;
 	if(currentMonth > 12) {
 		currentYear++;
 		currentMonth = currentMonth - 12;
 	}
 }
 
getTimezoneOffset()метод 
AS3 function getTimezoneOffset():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает разницу в минутах между местным временем компьютера и всемирным скоординированным временем (UTC).

Возвращает
Number — Число минут, которые необходимо добавить к значению местного времени компьютера, чтобы оно равнялось UTC. Если время компьютера опережает UTC, возвращается отрицательное значение.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getTimezoneOffset(), который извлекает разницу (в минутах) между моментом создания объекта now и всемирным временем. Затем смещение временного пояса преобразуется в часы путем деления результата на 60.

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);
getUTCDate()метод 
AS3 function getUTCDate():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date день месяца (целое число от 1 до 31) по всемирному скоординированному времени (UTC).

Возвращает
Number — День месяца в формате UTC (1 — 31), который представляет объект Date.

См. также


Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызывается метод getUTCDate(), который извлекает число месяца в формате UTC.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30
getUTCDay()метод 
AS3 function getUTCDay():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date день недели (0 — воскресенье, 1 — понедельник, и т.д.) по всемирному скоординированному времени (UTC).

Возвращает
Number — День недели в формате UTC (0 — 6), который представляет объект Date.

См. также


Пример

В следующем примере создается новый объект Array weekDayLabels с элементами [Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday] и новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). После этого дважды вызывается метод getUTCDay(), который сначала показывает число месяца в виде цифры 6, а затем показывает день недели с помощью weekDayLabels в формате UTC.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday
getUTCFullYear()метод 
AS3 function getUTCFullYear():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date четырехзначный год по всемирному скоординированному времени (UTC).

Возвращает
Number — Четырехзначный год по всемирному скоординированному времени, который представляется объектом Date.

См. также


Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызывается метод getUTCFullYear(), который извлекает четырехзначный год в формате UTC.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974
getUTCHours()метод 
AS3 function getUTCHours():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date час дня (целое число от 0 до 23) по всемирному скоординированному времени (UTC).

Возвращает
Number — День недели в формате UTC (от 0 до 23), который представляет объект Date.

См. также


Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызываются методы getHours() и getMinutes(), которые извлекают часы и минуты в 24-часовом формате. В итоге создается строка localTime, которая присваивается результату вызова функции getUSClockTime(), которая, в свою очередь, снова вызывает методы getHours() и getMinutes(), указывающее время 03:05 PM. Последней создается переменная String utcTime. Метод создания аналогичен методу создания localTime, и в данном случае получается одинаковый результат.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}
getUTCMilliseconds()метод 
AS3 function getUTCMilliseconds():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date число миллисекунд (целое число от 0 до 999) по всемирному скоординированному времени (UTC).

Возвращает
Number — Фрагмент объекта Date с миллисекундами (UTC).

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getUTCMilliseconds(), который извлекает из объекта Date now число миллисекунд на момент создания

var now:Date = new Date();
trace(now.getUTCMilliseconds());
getUTCMinutes()метод 
AS3 function getUTCMinutes():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date число минут (целое число от 0 до 59) по всемирному скоординированному времени (UTC).

Возвращает
Number — Фрагмент объекта Date с минутами (UTC).

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getUTCMilliseconds(), который извлекает из объекта Date now число минут на момент создания

var now:Date = new Date();
trace(now.getUTCMinutes());
getUTCMonth()метод 
AS3 function getUTCMonth():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date месяц (от 0 [январь] до 11 [декабрь]) по всемирному скоординированному времени (UTC).

Возвращает
Number — Фрагмент объекта Date с месяцем (UTC).

См. также


Пример

В следующем примере создается новый объект Array monthLabels с элементами от January до December и новый объект Date now без параметров. Затем дважды вызывается метод getUTCMonth(), который сначала возвращает номер месяца, а затем указывает месяц создания объекта Date now.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);
getUTCSeconds()метод 
AS3 function getUTCSeconds():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает из объекта Date число секунд (целое число от 0 до 59) по всемирному скоординированному времени (UTC).

Возвращает
Number — Фрагмент объекта Date с секундами (UTC).

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getUTCSeconds(), который извлекает из объекта Date now число минут на момент создания

var now:Date = new Date();
trace(now.getUTCSeconds());
parse()метод 
public static function parse(date:String):Number

Преобразует строку, представляющую дату, в число, равное количеству миллисекунд с полуночи 1 января 1970 года по Гринвичу (UTC).

Параметры

date:String — Строка, представляющая дату, соответствующую выходному формату Date.toString(). Формат выводимой даты Date.toString() выглядит следующим образом:
     Day Mon DD HH:MM:SS TZD YYYY
     

Например,

     Wed Apr 12 15:30:17 GMT-0700 2006
     

Идентификатор временного пояса (TZD) всегда представлен в формате GMT-ЧЧMM или UTC-ЧЧMM, указывающем на сдвиг часов и минут, относящийся к среднему времени по Гринвичу (GMT), которое сейчас называют также всемирным скоординированным временем (UTC). Месяц и день разделяются в году косой чертой (/) или пробелом, но никогда дефисом (-). В число других поддерживаемых форматов входят следующие (можно включить частичные представления этих форматов; то есть месяц, день и год).

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD
     

Возвращает
Number — Число, выражающее количество миллисекунд, прошедшее с 1 января 1970 года по всемирному скоординированному времени (UTC).

См. также


Пример

В следующем примере строка с данными присваивается параметру dateParsed, который соответствует 30 ноября 1974 г. Затем вызывается метод Date.parse(), преобразующий эту дату в число миллисекунд, прошедших с 1 января 1970 г.
var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000
setDate()метод 
AS3 function setDate(day:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает день месяца по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущен Flash Player.

Параметры

day:Number — Целое число от 1 до 31.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызывается метод getDate(), определяющий день месяца. Вызывается метод setDate() с параметром day, которому присваивается значение 20, а затем снова выполняется вызов метода getDate(), определяющего недавно выбранное число месяца.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20
setFullYear()метод 
AS3 function setFullYear(year:Number, month:Number, day:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает год по местному времени и возвращает новое время в миллисекундах. Если указаны параметры month и day, им присваивается местное время. Местное время определяется операционной системой, в которой запущен Flash Player.

Вызов этого метода не приводит к модификации других полей объекта Date, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

year:Number — Четырехзначное число, определяющее год. Двухзначные числа не представляют четырехзначные; например, "99" соответствует не 1999, а 99 году.
 
month:Number — Целое число от 0 (январь) до 11 (декабрь).
 
day:Number — Число от 1 до 31.

Возвращает
Number — Новое время в миллисекундах.

См. также


Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). После этого вызывается метод getFullYear(), который извлекает четырехзначное обозначение года. Затем вызывается метод setFullYear() с параметром year, которому присваивается значение 2000, а затем снова выполняется вызов метода getFullYear(), определяющего недавно выбранный год.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000
setHours()метод 
AS3 function setHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает час по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущен Flash Player.

Параметры

hour:Number — Целое число от 0 (полночь) до 23 (11 часов вечера).
 
minute:Number — Целое число от 0 до 59.
 
second:Number — Целое число от 0 до 59.
 
millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызываются методы getHours() и getMinutes(), определяющие часы и минуты. После этого выполняется вызов метода setHours() с параметром hour, которому присваивается значение 12, а затем методы getHours() и getMinutes() вызываются снова, определяя только что установленное время в часах и минутах.

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20
setMilliseconds()метод 
AS3 function setMilliseconds(millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает количество миллисекунд по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущен Flash Player.

Параметры

millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getMilliseconds(), который извлекает значение миллисекунд на момент создания объекта now. Затем снова вызывается новый объект Date before. При этом выполняется дополнительный вызов метода setMilliseconds(), где параметру millisecond присвоено значение 4 и метода getMilliseconds(), извлекающего недавно установленное значение в миллисекундах.

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());
setMinutes()метод 
AS3 function setMinutes(minute:Number, second:Number, millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает количество минут по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущен Flash Player.

Параметры

minute:Number — Целое число от 0 до 59.
 
second:Number — Целое число от 0 до 59.
 
millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getMinutes(), который извлекает значение миллисекунд на момент создания объекта now. Затем снова вызывается новый объект Date before. При этом выполняется дополнительный вызов метода setMinutes(), где параметру minute присвоено значение 0 и метода getMinutes(), извлекающего недавно установленное значение в минутах.

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());
setMonth()метод 
AS3 function setMonth(month:Number, day:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает месяц и (при необходимости) день месяца по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущен Flash Player.

Параметры

month:Number — Целое число от 0 (январь) до 11 (декабрь).
 
day:Number — Целое число от 1 до 31.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Array monthLabels с элементами от January до December и новый объект месяца now без параметров. Затем вызывается метод getMonth(), который извлекает значение месяца на момент создания объекта now. Затем вызывается метод setMonth() с параметром year, которому присваивается значение 0, а затем снова выполняется вызов метода getMonth(), определяющего недавно выбранный месяц.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January
setSeconds()метод 
AS3 function setSeconds(second:Number, millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает количество секунд по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущен Flash Player.

Параметры

second:Number — Целое число от 0 до 59.
 
millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getseconds(), который извлекает значение секунд на момент создания объекта now. Затем вызывается метод setSeconds(), где параметр second принимает значения 0, а после этого снова вызывается метод getSeconds(), определяющий недавно установленное время в секундах.

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0
setTime()метод 
AS3 function setTime(millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает дату в миллисекундах с полуночи 1 января 1970 года и возвращает новое время в миллисекундах.

Параметры

millisecond:Number — Целое число, для которого 0 означает полночь 1 января по универсальному времени (UTC).

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод setTime(), где параметру millisecond присвоено значение -1292601600000, который устанавливает время Tue Jan 15 00:00:00 GMT-0800 1929.

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929
setUTCDate()метод 
AS3 function setUTCDate(day:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает день месяца по Гринвичу (UTC) и возвращает новое время в миллисекундах. Вызов этого метода не приводит к модификации других полей объекта Date, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

day:Number — Целое число от 1 до 31.

Возвращает
Number — Новое время в миллисекундах.

См. также


Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Вызывается метод getUTCDate(), правильно возвращающий день месяца. Затем вызывается метод setUTCDate(), где параметру day присвоено значение 1, а инструкция trace() подтверждает правильность установки даты.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974
setUTCFullYear()метод 
AS3 function setUTCFullYear(year:Number, month:Number, day:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает год по Гринвичу (UTC) и возвращает новое время в миллисекундах.

При желании этот метод может установить также месяц и день месяца. Вызов этого метода не приводит к модификации других полей, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

year:Number — Целое число, которое представляет собой год в полном четырехзначном формате (например, 2000).
 
month:Number — Целое число от 0 (январь) до 11 (декабрь).
 
day:Number — Целое число от 1 до 31.

Возвращает
Number — Целое число.

См. также


Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Вызывается метод getUTCFullYear(), который правильно возвращает четырехзначный год. Затем вызывается метод setUTCFullYear(), где параметру year присвоено значение 1975, а инструкция trace() подтверждает правильность установки года.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975
setUTCHours()метод 
AS3 function setUTCHours(hour:Number, minute:Number, second:Number, millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает час по Гринвичу (UTC) и возвращает новое время в миллисекундах. При желании можно также указать минуты, секунды и миллисекунды.

Параметры

hour:Number — Целое число от 0 (полночь) до 23 (11 часов вечера).
 
minute:Number — Целое число от 0 до 59.
 
second:Number — Целое число от 0 до 59.
 
millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20). Затем вызываются методы getHours(), getMinutes(), getUTCHours и getUTCMinutes, определяющие часы и минуты. После этого вызывается метод setUTCHours() с параметром hour, для которого выбрано значение 12. И, наконец, повторно вызываются методы getHours(), getMinutes(), getUTCHours() и getUTCMinutes() и правильно показывается обновленное время в часах.

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20
setUTCMilliseconds()метод 
AS3 function setUTCMilliseconds(millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает количество миллисекунд по Гринвичу (UTC) и возвращает новое время в миллисекундах.

Параметры

millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getUTCMilliseconds(), который извлекает значение миллисекунд (UTC) на момент создания объекта now. Затем снова вызывается новый объект Date before. При этом выполняется дополнительный вызов метода setUTCMilliseconds(), где параметру millisecond присвоено значение 4 и метода getUTCMilliseconds(), извлекающего недавно установленное значение в миллисекундах.


var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());
setUTCMinutes()метод 
AS3 function setUTCMinutes(minute:Number, second:Number, millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает количество минут по Гринвичу (UTC) и возвращает новое время в миллисекундах. При желании можно указать секунды и миллисекунды.

Параметры

minute:Number — Целое число от 0 до 59.
 
second:Number — Целое число от 0 до 59.
 
millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getUTCMinutes(), который извлекает значение минут (UTC) на момент создания объекта now. Затем снова вызывается новый объект Date before. При этом выполняется дополнительный вызов метода setUTCMinutes(), где параметру minute присвоено значение 0 и метода getUTCMinutes(), извлекающего недавно установленное значение в минутах.

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());
setUTCMonth()метод 
AS3 function setUTCMonth(month:Number, day:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает месяц и (при необходимости) день месяца по Гринвичу (UTC) и возвращает новое время в миллисекундах. Вызов этого метода не приводит к модификации других полей, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

month:Number — Целое число от 0 (январь) до 11 (декабрь).
 
day:Number — Целое число от 1 до 31.

Возвращает
Number — Новое время в миллисекундах.

См. также


Пример

В следующем примере создается новый объект Array UTCMonthLabels с элементами от January до December и новый объект UTCMonth now без параметров. Затем вызывается метод getUTCMonth(), который извлекает значение месяца (UTC) на момент создания объекта now. После этого вызывается метод setUTCMonth() с параметром month, которому присваивается значение 0, а затем снова выполняется вызов метода getUTCMonth(), определяющего недавно выбранный месяц.

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January
setUTCSeconds()метод 
AS3 function setUTCSeconds(second:Number, millisecond:Number):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Задает количество секунд и (при необходимости) миллисекунд по Гринвичу (UTC) и возвращает новое время в миллисекундах.

Параметры

second:Number — Целое число от 0 до 59.
 
millisecond:Number — Целое число от 0 до 999.

Возвращает
Number — Новое время в миллисекундах.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getUTCSeconds(), который извлекает значение секунд на момент создания объекта now. После этого вызывается метод setUTCSeconds(), где параметр second принимает значение 0, а потом снова вызывается метод getUTCSeconds(), определяющий недавно установленное время в секундах.

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0
toDateString()метод 
AS3 function toDateString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает строковое представление дня и даты без времени или часового пояса. Сравните это с указанными ниже методами.

Возвращает
String — Строковое представление дня и даты.

См. также


Пример

В следующем примере создается новый объект Date now без параметров, а затем вызываются следующие методы в инструкции trace().
  • toString: показывает все параметры now на момент создания объекта now.
  • toDateString(): показывает значения параметров day, month и year на момент создания объекта now.

var now:Date = new Date();
trace(now);
trace(now.toDateString());
toLocaleDateString()метод 
AS3 function toLocaleDateString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает строковое представление дня и даты без времени или часового пояса. Этот метод возвращает то же значение, что и Date.toDateString. Сравните это с указанными ниже методами.

Возвращает
StringСтроковое представление дня и даты.

См. также

toLocaleString()метод 
AS3 function toLocaleString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает строковое представление дня, даты и времени по местному времени. Сравните это с методом Date.toString(), возвращающим ту же информацию (а также часовой пояс), относящуюся к году, указанному в конце строки.

Возвращает
String — Строковое представление объекта Date в местном часовом поясе.
toLocaleTimeString()метод 
AS3 function toLocaleTimeString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает строковое представление времени без дня, даты, года или часового пояса. Сравните это с методом Date.toTimeString(), который возвращает время и часовой пояс.

Возвращает
String — Строковое представление времени и часового пояса.

См. также

toString()метод 
AS3 function toString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает строковое представление дня, даты, времени и часового пояса. Формат выводимой даты:

     Day Mon Date HH:MM:SS TZD YYYY
     

Например,

     Wed Apr 12 15:30:17 GMT-0700 2006
     

Возвращает
String — Строковое представление объекта Date.

Пример

В следующем примере создается новый объект Date now без параметров, а затем вызывается метод toString в инструкции trace(), который показывает параметры объекта now на момент создания now.


var now:Date = new Date();
trace(now);
toTimeString()метод 
AS3 function toTimeString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает строковое представление времени и часового пояса без дня и даты. Сравните это с методом Date.toDateString(), который возвращает только день и дату.

Возвращает
String — Строковое представление времени и часового пояса.

См. также

toUTCString()метод 
AS3 function toUTCString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает строковое представление дня, даты и времени по Гринвичу (UTC). Например, дата 1 февраля 2005 г. выглядит как Tue Feb 1 00:00:00 2005 UTC.

Возвращает
String — Строковое представление объекта Date по всемирному скоординированному времени.

См. также

UTC()метод 
public static function UTC(year:Number, month:Number, date:Number = 1, hour:Number = 0, minute:Number = 0, second:Number = 0, millisecond:Number = 0):Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает число миллисекунд от полуночи 1 января 1970 года по Гринвичу до момента, заданного параметрами. В этом методе используется всемирное скоординированное время, а в конструкторе Date — местное время.

Этот метод полезен, если требуется передать дату в формате всемирного скоординированного времени (UTC) конструктору класса Date. Поскольку конструктор класса данных Date поддерживает в качестве аргумента смещение в миллисекундах, можно воспользоваться методом Date.UTC(), чтобы преобразовать дату в формате UTC в соответствующее смещение, выраженное в миллисекундах, а затем отправить это смещение в качестве аргумента конструктору класса Date:

Параметры

year:Number — Целое четырехзначное число, указывающее на год (например, 2000).
 
month:Number — Целое число от 0 (январь) до 11 (декабрь).
 
date:Number (default = 1) — Целое число от 1 до 31.
 
hour:Number (default = 0) — Целое число от 0 (полночь) до 23 (11 часов вечера).
 
minute:Number (default = 0) — Целое число от 0 до 59.
 
second:Number (default = 0) — Целое число от 0 до 59.
 
millisecond:Number (default = 0) — Целое число от 0 до 999.

Возвращает
Number — Количество миллисекунд, прошедших с 1 января 1970 г. до указанных даты и времени.

Пример

В следующем примере создается объект Date someBirthday с параметрами year (1974), month (10 = ноябрь), day (30), hour (1) и minute (20) по местному времени. Затем выполняется вызов UTC() в методе setTime(), который приводит к сбросу значений этих параметров и установке всемирного времени.

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());
valueOf()метод 
AS3 function valueOf():Number

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9

Возвращает для объекта Date число миллисекунд с полуночи 1 января 1970 года по всемирному скоординированному времени.

Возвращает
Number — Количество миллисекунд с 1 января 1970 г., выражаемое объектом Date.

Пример

В следующем примере создается новый объект Date now без параметров. Затем вызывается метод getTime(), который определяет количество миллисекунд между временем создания now и полуночью 1 января 1970 г. После этого вызывается метод valueOf(), определяющий тоже самое.


var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());
Примеры Как пользоваться примерами
DateExample.as

В следующем примере показаны различные применения конструктора Date(), присваивающего следующие переменные:

package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}