Главная / Action Script 3
Пакетfl.data
Классpublic class DataProvider
НаследованиеDataProvider Inheritance EventDispatcher Inheritance Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

В классе DataProvider предусмотрены методы и свойства, которые позволяют запрашивать и модифицировать данные в любом компоненте, основанном на списке (например, List, DataGrid, TileList и ComboBox).

Поставщик данных — это линейная коллекция элементов, которая служат источником данных (например, массив). Каждый элемент в поставщике данных является объектом или объектом XML, содержащим одно или несколько полей данных. Элементы, которые содержатся в поставщике данных, можно вызвать, указав их индекс, при помощи метода DataProvider.getItemAt().

Посмотреть примеры



Общедоступные свойства
 СвойствоОпределено
 Inheritedconstructor : Object
Ссылка на объект класса или функцию конструктора для данного экземпляра объекта.
Object
  length : uint
[только для чтения] Число элементов, содержащихся в поставщике данных.
DataProvider
 Inheritedprototype : Object
[статические] Ссылка на модель объекта класса или функции.
Object
Общедоступные методы
 МетодОпределено
  
DataProvider(value:Object = null)
Создает новый объект DataProvider с использованием списка, экземпляра XML или массива объектов данных в качестве источника данных.
DataProvider
 Inherited
addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Регистрирует объект прослушивателя события в объекте EventDispatcher, в результате чего прослушиватель будет получать уведомления о событиях.
EventDispatcher
  
Добавляет элемент в конец набора данных, предоставляемого поставщиком данных.
DataProvider
  
addItemAt(item:Object, index:uint):void
Добавляет новый элемент к поставщику данных в заданном положении индекса.
DataProvider
  
Добавляет несколько элементов в конец набора данных компонента DataProvider и отправляет событие DataChangeType.ADD.
DataProvider
  
addItemsAt(items:Object, index:uint):void
Добавляет несколько элементов в поставщик данных по указанному индексу и отправляет событие DataChangeType.ADD.
DataProvider
  
Создает копию текущего объекта DataProvider.
DataProvider
  
Дописывает указанные элементы в конец набора данных, предоставляемых текущим поставщиком данных.
DataProvider
 Inherited
Передает событие в поток событий.
EventDispatcher
  
Возвращает элемент из заданного положения индекса.
DataProvider
  
Возвращает индекс заданного элемента.
DataProvider
 Inherited
Проверяет наличие у объекта EventDispatcher прослушивателей событий, которые зарегистрированы для получения уведомлений о событиях определенного типа.
EventDispatcher
 Inherited
Показывает, определено ли заданное свойство для объекта.
Object
  
Аннулирует все элементы данных, содержащиеся в компоненте DataProvider, и отправляет событие DataChangeEvent.INVALIDATE_ALL.
DataProvider
  
Аннулирует указанный элемент.
DataProvider
  
Аннулирует элемент из заданного положения индекса.
DataProvider
 Inherited
Показывает, есть ли экземпляр класса Object в цепи прототипов объекта, заданного в качестве параметра.
Object
  
merge(newData:Object):void
Добавляет указанные данные к существующим данным, предоставляемым поставщиком данных, и удаляет все повторяющиеся элементы.
DataProvider
 Inherited
Показывает наличие заданного свойства и его перечисляемость.
Object
  
Удаляет все элементы из поставщика данных и передает событие DataChangeType.REMOVE_ALL.
DataProvider
 Inherited
removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void
Удаляет прослушиватель из объекта EventDispatcher.
EventDispatcher
  
Удаляет указанный элемент из набора данных, предоставляемых поставщиком данных, и отправляет событие DataChangeType.REMOVE.
DataProvider
  
Удаляет элемент в заданном положении индекса и передает событие DataChangeType.REMOVE.
DataProvider
  
replaceItem(newItem:Object, oldItem:Object):Object
Заменяет существующий элемент новым и отправляет событие DataChangeType.REPLACE.
DataProvider
  
Заменяет элемент с указанным индексом и отправляет событие DataChangeType.REPLACE.
DataProvider
 Inherited
Задает доступность динамического свойства для операций цикла.
Object
  
sort(... sortArgs):*
Сортирует элементы в поставщике данных и отправляет событие DataChangeType.SORT.
DataProvider
  
sortOn(fieldName:Object, options:Object = null):*
Сортирует элементы, содержащиеся в поставщике данных, по указанному полю и отправляет событие DataChangeType.SORT.
DataProvider
  
Создает объект Array, представляющий данные, содержащиеся в поставщике данных.
DataProvider
  
Создает строковое представление данных, содержащихся в поставщике данных.
DataProvider
 Inherited
Возвращает элементарное значение заданного объекта.
Object
 Inherited
Проверяет, зарегистрирован ли прослушиватель событий в объекте EventDispatcher или в любом из его предков для получения уведомлений о событиях определенного типа.
EventDispatcher
События
 Событие Сводка Определено
 Inherited[многоадресное событие] Отправляется, когда проигрыватель Flash Player перемещается в фокус операционной системы и становится активным.EventDispatcher
  Отправляется после изменения данных.DataProvider
 Inherited[многоадресное событие] Отправляется, когда проигрыватель Flash Player покидает фокус операционной системы и становится неактивным.EventDispatcher
  Отправляется перед изменением данных.DataProvider
Сведения о свойстве
lengthсвойство
length:uint  [только для чтения]

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Число элементов, содержащихся в поставщике данных.



Реализация
    public function get length():uint

Пример
В следующем примере создается экземпляр компонента List, а размер списка изменяется, исходя из количества элементов в поставщике данных:

import fl.controls.List;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({label:"Item 1"});
dp.addItem({label:"Item 2"});
dp.addItem({label:"Item 3"});
dp.addItem({label:"Item 4"});

var myList:List = new List();
myList.dataProvider = dp;
myList.rowHeight = 35;
myList.rowCount = dp.length;
myList.move(10, 10);
addChild(myList);
Сведения о конструкторе
DataProvider()Конструктор
public function DataProvider(value:Object = null)

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Создает новый объект DataProvider с использованием списка, экземпляра XML или массива объектов данных в качестве источника данных.

Параметры
value:Object (default = null) — Данные, используемые для создания DataProvider.

Пример

В следующем примере с помощью метода addItem() создается новый поставщик данных:

import fl.controls.ComboBox;
import fl.data.DataProvider;
 
var dp:DataProvider = new DataProvider();
dp.addItem({label:"item 1a"});
dp.addItem({label:"item 2a"});

var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);

В следующем примере поставщик данных заполняется с помощью объекта Array:

import fl.controls.ComboBox;
import fl.data.DataProvider;

var arr:Array = new Array();
arr.push({label:"item 1b"});
arr.push({label:"item 2b"});

var dp:DataProvider = new DataProvider(arr);

var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);

В следующем примере поставщик данных заполняется с помощью объекта XML с атрибутами:

import fl.controls.ComboBox;
import fl.data.DataProvider;

var xml:XML = <items>
        <item label="item 1c" />
        <item label="item 2c" />
    </items>;

var dp:DataProvider = new DataProvider(xml);

var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);

В следующем примере поставщик данных заполняется с помощью объекта XML с дочерними узлами:

import fl.controls.ComboBox;
import fl.data.DataProvider;

var xml:XML = <items>
        <item>
            <label>item 1d</label>
        </item>
        <item>
            <label>item 2d</label>
        </item>
    </items>;

var dp:DataProvider = new DataProvider(xml);

var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
Сведения о методе
addItem()метод
public function addItem(item:Object):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Добавляет элемент в конец набора данных, предоставляемого поставщиком данных.

Параметры

item:Object — Элемент, добавляемый в конец текущего поставщика данных.

См. также


Пример

В следующем примере с помощью метода addItem() создается новый поставщик данных:

import fl.controls.ComboBox;
import fl.data.DataProvider;
 
var dp:DataProvider = new DataProvider();
dp.addItem({label:"item 1a"});
dp.addItem({label:"item 2a"});

var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
addItemAt()метод 
public function addItemAt(item:Object, index:uint):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Добавляет новый элемент к поставщику данных в заданном положении индекса. Если указанный индекс превышает длину поставщика данных, то он игнорируется.

Параметры

item:Object — Объект, содержащий данные добавляемого элемента.
 
index:uint — Индекс добавления элемента.


Выдает
RangeError — Указанный индекс меньше 0, либо больше или равен длине поставщика данных.

См. также

addItems()метод 
public function addItems(items:Object):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Добавляет несколько элементов в конец набора данных DataProvider и отправляет событие DataChangeType.ADD. Элементы, которые добавляются в том порядке, в котором они указаны.

Параметры

items:Object — Элементы, добавляемые в конец поставщика данных.

См. также


Пример

В следующем примере используется метод addItems() для добавления нескольких элементов в поставщик данных:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var arr:Array = [{col1:"1.A", col2:"1.B"}, {col1:"2.A", col2:"2.B"}]

var dp:DataProvider = new DataProvider();
dp.addItems(arr);
trace(dp.length); // 2

var c1:DataGridColumn = new DataGridColumn("col1");
var c2:DataGridColumn = new DataGridColumn("col2");

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.dataProvider = dp;
myDataGrid.setSize(200, 160);
myDataGrid.move(10, 10);
addChild(myDataGrid);
addItemsAt()метод 
public function addItemsAt(items:Object, index:uint):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Добавляет несколько элементов в поставщик данных по указанному индексу и отправляет событие DataChangeType.ADD.

Параметры

items:Object — Элементы, добавляемые в поставщик данных.
 
index:uint — Индекс положения вставки элементов.


Выдает
RangeError — Указанный индекс меньше 0, либо больше или равен длине поставщика данных.

См. также

clone()метод 
public function clone():DataProvider

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Создает копию текущего объекта DataProvider.

Возвращает
DataProvider — Новый экземпляр объекта DataProvider.
concat()метод 
public function concat(items:Object):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Дописывает указанные элементы в конец набора данных, предоставляемых текущим поставщиком данных. Этот метод отправляет событие DataChangeType.ADD.

Параметры

items:Object — Элементы, добавляемые в поставщик данных.

См. также

getItemAt()метод 
public function getItemAt(index:uint):Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Возвращает элемент из заданного положения индекса.

Параметры

index:uint — Местоположение возвращаемого элемента.

Возвращает
Object — Элемент в заданном положении индекса.

Выдает
RangeError — Указанный индекс меньше 0, либо больше или равен длине поставщика данных.

См. также

getItemIndex()метод 
public function getItemIndex(item:Object):int

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Возвращает индекс заданного элемента.

Параметры

item:Object — Искомый элемент.

Возвращает
int — Индекс возвращаемого элемента, или -1, если указанный элемент не найден.

См. также

invalidate()метод 
public function invalidate():void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Аннулирует все элементы данных, содержащиеся в компоненте DataProvider, и отправляет событие DataChangeEvent.INVALIDATE_ALL. Элементы аннулируются после внесения в них изменений; DataProvider автоматически перерисовывает аннулированный элемент.

См. также

invalidateItem()метод 
public function invalidateItem(item:Object):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Аннулирует указанный элемент. Элемент аннулируется после внесения в него изменений; DataProvider автоматически перерисовывает аннулированный элемент.

Параметры

item:Object — Аннулируемый элемент.

См. также

invalidateItemAt()метод 
public function invalidateItemAt(index:int):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Аннулирует элемент из заданного положения индекса. Элемент аннулируется после внесения в него изменений; DataProvider автоматически перерисовывает аннулированный элемент.

Параметры

index:int — Индекс аннулируемого элемента.


Выдает
RangeError — Указанный индекс меньше 0, либо больше или равен длине поставщика данных.

См. также

merge()метод 
public function merge(newData:Object):void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Добавляет указанные данные к существующим данным, предоставляемым поставщиком данных, и удаляет все повторяющиеся элементы. Этот метод отправляет событие DataChangeType.ADD.

Параметры

newData:Object — Данные, объединяемые поставщиком данных.

См. также

removeAll()метод 
public function removeAll():void

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Удаляет все элементы из поставщика данных и отправляет событие DataChangeType.REMOVE_ALL.

См. также

removeItem()метод 
public function removeItem(item:Object):Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Удаляет указанный элемент из поставщика данных и отправляет событие DataChangeType.REMOVE.

Параметры

item:Object — Удаляемый элемент.

Возвращает
Object — Удаленный элемент.

См. также

removeItemAt()метод 
public function removeItemAt(index:uint):Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Удаляет элемент в заданном положении индекса и передает событие DataChangeType.REMOVE.

Параметры

index:uint — Индекс удаляемого элемента.

Возвращает
Object — Удаленный элемент.

Выдает
RangeError — Указанный индекс меньше 0, либо больше или равен длине поставщика данных.

См. также

replaceItem()метод 
public function replaceItem(newItem:Object, oldItem:Object):Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Заменяет существующий элемент новым и отправляет событие DataChangeType.REPLACE.

Параметры

newItem:Object — Заменяемый элемент.
 
oldItem:Object — Элемент-заместитель.

Возвращает
Object — Замененный элемент.

Выдает
RangeError — Элемент не удалось найти в поставщике данных.

См. также

replaceItemAt()метод 
public function replaceItemAt(newItem:Object, index:uint):Object

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Заменяет элемент с указанным индексом и отправляет событие DataChangeType.REPLACE.

Параметры

newItem:Object — Элемент-заместитель.
 
index:uint — Индекс заменяемого элемента.

Возвращает
Object — Замененный элемент.

Выдает
RangeError — Указанный индекс меньше 0, либо больше или равен длине поставщика данных.

См. также

sort()метод 
public function sort(... sortArgs):*

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Сортирует элементы в поставщике данных и отправляет событие DataChangeType.SORT.

Параметры

... sortArgs — Аргументы, используемые при сортировке.

Возвращает
* — Возвращаемое значение зависит от того, получает ли метод какие-либо аргументы. Дополнительную информацию см. в методе Array.sort(). Этот метод возвращает 0, когда свойству sortOption присваивается значение Array.UNIQUESORT.

См. также

sortOn()метод 
public function sortOn(fieldName:Object, options:Object = null):*

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Сортирует элементы, содержащиеся в поставщике данных, по указанному полю и отправляет событие DataChangeType.SORT. Указанное поле может являться строкой или массивом строковых значений, определяющих несколько сортируемых полей в порядке старшинства.

Параметры

fieldName:Object — Поле элемента, по которому выполняется сортировка. Это значение может быть строкой или массивом строковых значений.
 
options:Object (default = null) — Параметры сортировки.

Возвращает
* — Возвращаемое значение зависит от того, получает ли метод какие-либо аргументы. Дополнительную информацию см. в описании метода Array.sortOn(). Если свойству sortOption присвоено значение Array.UNIQUESORT, этот метод возвращает 0.

См. также

toArray()метод 
public function toArray():Array

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Создает объект Array, представляющий данные, содержащиеся в поставщике данных.

Возвращает
Array — Объект Array, представляющий данные, содержащиеся в поставщике данных.
toString()метод 
override public function toString():String

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Создает строковое представление данных, содержащихся в поставщике данных.

Возвращает
String — Строковое представление данных, содержащихся в поставщике данных.
Сведения о событии
dataChange Событие
Тип объекта события: fl.events.DataChangeEvent
свойство DataChangeEvent.type = fl.events.DataChangeEvent.DATA_CHANGE

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Отправляется после изменения данных.

Задает значение свойства type для объекта события dataChange.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
changeTypeОпределяет тип внесенного изменения.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
endIndexОпределяет индекс последнего измененного элемента.
itemsМассив, в котором перечислены измененные элементы.
startIndexОпределяет индекс первого измененного элемента.
targetОбъект, отправивший событие. Адресат не всегда является объектом, выполняющим прослушивание события. Воспользуйтесь свойством currentTarget для доступа к объекту, прослушивающему событие.

См. также

preDataChange Событие  
Тип объекта события: fl.events.DataChangeEvent
свойство DataChangeEvent.type = fl.events.DataChangeEvent.PRE_DATA_CHANGE

Язык версии : ActionScript 3.0
Версии среды выполнения:  1.0 9.0.28.0

Отправляется перед изменением данных.

Задает значение свойства type для объекта события preDataChange. Этот объект события отправляется перед тем, как в данные компонента вносятся изменения.

Данное событие имеет следующие свойства.

СвойствоЗначение
bubblesfalse
cancelablefalse; нет поведения по умолчанию для отмены.
changeTypeОпределяет тип вносимого изменения.
currentTargetОбъект, активно обрабатывающий объект Event с помощью прослушивателя событий.
endIndexУказывает индекс последнего изменяемого элемента.
itemsМассив, в котором перечислены изменяемые элементы.
startIndexУказывает индекс первого изменяемого элемента.
targetОбъект, отправивший событие. Адресат не всегда является объектом, выполняющим прослушивание события. Воспользуйтесь свойством currentTarget для доступа к объекту, прослушивающему событие.

См. также

Примеры Как пользоваться примерами
DataProviderExample.as

В этом примере показано, как с помощью поставщиков данных можно сохранять содержимое нескольких сеток данных.

Чтобы применить этот пример на практике, выполните следующие действия.

  1. Добавьте в библиотеку компоненты Label, Button, ComboBox, TextInput и DataGrid.
  2. Сохраните этот код под именем DataProviderExample.as в том же каталоге, где и FLA-файл.
  3. Присвойте классу Document в FLA-файле значение DataProviderExample.
package
{
    import fl.controls.Button;
    import fl.controls.ComboBox;
    import fl.controls.DataGrid;
    import fl.controls.Label;
    import fl.controls.TextInput;
    import fl.data.DataProvider;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.text.TextFieldAutoSize;
    
    public class DataProviderExample extends Sprite
    {        
        private var southern:DataGrid;
        private var northern:DataGrid;
        private var world:DataGrid;
        private var southernRoster:DataProvider;
        private var northernRoster:DataProvider;
        private var leagueCB:ComboBox;
        private var nameTI:TextInput;
        private var goalsTI:TextInput;
        private var submitBtn:Button;

        public function DataProviderExample() {
            southernRoster = new DataProvider();
            northernRoster = new DataProvider();
            
            createDataGrids();
            createUI();
        }

        private function createUI():void {
            var description:Label = new Label();
            description.text = "Enter player's name, goals scored, and hemisphere of origin:";
            description.autoSize = TextFieldAutoSize.LEFT;
            nameTI = new TextInput();
            goalsTI = new TextInput();
            
            var submitBtn:Button = new Button();
            submitBtn.label = "Submit Player";
            submitBtn.addEventListener(MouseEvent.CLICK, submitPlayer);
            
            leagueCB = new ComboBox();
            leagueCB.addItem( { label:"Northern", data: 0 } );
            leagueCB.addItem( { label:"Southern", data: 1 } );
            
            description.move(10,10);
            nameTI.move(10,40);
            nameTI.setSize(150,24);
            goalsTI.move(170,40);
            goalsTI.setSize(40,24);
            leagueCB.move(220,40);
            leagueCB.setSize(120,24);
            submitBtn.move(350,40);
            goalsTI.restrict = "0123456789";
            
            addChild(description);
            addChild(leagueCB);
            addChild(submitBtn);
            addChild(nameTI);
            addChild(goalsTI);
        }
        private function submitPlayer(e:MouseEvent):void {
            if(nameTI.text != "" && goalsTI.text != "") {
                var targetRoster:DataProvider;

                if(leagueCB.selectedItem.label == "Southern") {
                    targetRoster = southernRoster;
                }
                else {
                    targetRoster = northernRoster;
                }
    
                targetRoster.addItem( { Name: nameTI.text, Goals: goalsTI.text } );
                
                var worldRoster:DataProvider = southernRoster.clone();
                worldRoster.merge(northernRoster);
                worldRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
                southernRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
                northernRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
                
                world.dataProvider = worldRoster;
                
                nameTI.text = "";
                goalsTI.text = "";
            }
        }        

        private function createDataGrids():void {
            southern = new DataGrid();
            northern = new DataGrid();
            world = new DataGrid();
            southern.move(10,100);
            northern.move(180,100);
            world.move(350,100);
            southern.setSize(170, 250);
            northern.setSize(170, 250);
            world.setSize(170, 250);
            southern.columns = 
            northern.columns = 
            world.columns = [ "Name", "Goals" ];
            southern.dataProvider = southernRoster;
            northern.dataProvider = northernRoster;            
            addChild(southern);
            addChild(northern);
            addChild(world);

            var northernLabel:Label = new Label();
            northernLabel.autoSize = TextFieldAutoSize.LEFT;
            northernLabel.text = "Southern Hemisphere";
            northernLabel.move(10,75);
            addChild(northernLabel);
            var southernLabel:Label = new Label();
            southernLabel.autoSize = TextFieldAutoSize.LEFT;
            southernLabel.text = "Northern Hemisphere";
            southernLabel.move(180,75);
            addChild(southernLabel);
            var majorLabel:Label = new Label();
            majorLabel.autoSize = TextFieldAutoSize.LEFT;
            majorLabel.text = "World";
            majorLabel.move(350,75);
            addChild(majorLabel);
        }
    }
}